ポイント

Question

の2人の最も近い隣人を探す私は各点の2人の最も近い隣人に

データセット見つけたい：私はこのような何かをしようと

?POINT ?NEIGHBORS 
"p1" "p2; p3" 
"p2" "p1; p3" 
"p3" "p2; p4" 
"p4" "p2; p3" 

：

:p1 :has_position 1 . 
:p2 :has_position 2 . 
:p3 :has_position 3 . 
:p4 :has_position 4 . 

期待される結果を

SELECT ?POINT ?POS (group_concat(?idPointN;separator='; ')as ?NEIGHBORS) 
WHERE{ 
    ?idPoint :has_position ?POS . 
    ?idPointN :has_position ?POSN . FILTER (?idPoint != ?idPointN) 
} 
GROUP BY ?POINT ?POS 

これはポイントのすべての近傍を返します。私はgroup_concatの中にORDER BY(?POS-?POSN)とlimit 2のような何かをしたいのですが、どうすればよいかわかりません。

EDIT：

は、私はそれが最も近いことにより、各ポイントのすべてのネイバーの順序を私を与える

SELECT ?POINT ?NEIGHBOR 
WHERE{ 
    ?idPoint rdfs:label ?POINT . FILTER(?idN != ?idPoint) 
    ?idPoint :has_position ?POS . 


    ?idN rdfs:label ?NEIGHBOR . 
    ?idN :has_position ?POSN . 
} 
ORDER BY ?POINT abs(?POS-?POSN) 

このクエリを記述します。

どのように私は2つの最も近いことができますか？と同じ行に？

Answer 1

SPARQLでは何かのトップnを取得するクエリは本当に難しいですが、実際にはまだそれを行うには素晴らしい方法はありません。ほとんどの場合、奇妙なハックになる。最初に、プレフィックス宣言を持つデータ：

@prefix : <urn:ex:> 

:p1 :has_position 1 . 
:p2 :has_position 2 . 
:p3 :has_position 3 . 
:p4 :has_position 4 . 

次にクエリ。 選択行に長い文字列連結がありますが、それは質問に記載されているように接頭辞を取り除くだけです。この場合の「ハック」は、2つの最も近い点が、qおよびrの量が最小になることを認識しています。| p − q | + | p − r |となるので、その数量を計算して、qとrの値を取ってそれを私たちに渡すことができます。また、あなたがQとR上のいくつかの順序を課すことを確認する必要があります、または他の（あなたがQとRを単に入れ替える可能性があるので）あなたは、重複結果が得られます。今

prefix : <urn:ex:> 

select ?p (concat(strafter(str(?q),str(:)),", ",strafter(str(?r),str(:))) as ?neighbors) { 
    ?p :has_position ?pos1 . 
    ?q :has_position ?pos2 . 
    ?r :has_position ?pos3 . 
    filter(?p != ?q && ?p != ?r) 
    filter(str(?q) < str(?r)) 

    filter not exists { 
    ?qq :has_position ?pos22 . 
    ?rr :has_position ?pos33 . 
    filter(?p != ?qq && ?p != ?rr) 
    filter(str(?qq) < str(?rr)) 
    filter((abs(?pos1 - ?pos22) + abs(?pos1 - ?pos33)) < 
      (abs(?pos1 - ?pos2) + abs(?pos1 - ?pos3))) 
    } 
} 

------------------- 
| p | neighbors | 
=================== 
| :p1 | "p2, p3" | 
| :p2 | "p1, p3" | 
| :p3 | "p2, p4" | 
| :p4 | "p2, p3" | 
------------------- 

、あなたはまた、各のpのための最小限の量を見つけ、サブクエリでこれを行うことができ、その後、外側のクエリでは、QとRを見つけそれを生産値：

prefix : <urn:ex:> 

select ?p (concat(strafter(str(?q), str(:)), ", ", strafter(str(?r), str(:))) as ?neighbors) { 
    { select ?p (min(abs(?pos1 - ?pos2) + abs(?pos1 - ?pos3)) as ?d) { 
     ?p :has_position ?pos1 . 
     ?q :has_position ?pos2 . 
     ?r :has_position ?pos3 . 
     filter(?p != ?q && ?p != ?r) 
     filter(str(?q) < str(?r)) 
    } 
    group by ?p 
    } 

    ?p :has_position ?pos1 . 
    ?q :has_position ?pos2 . 
    ?r :has_position ?pos3 . 
    filter(?p != ?q && ?p != ?r) 
    filter(str(?q) < str(?r)) 
    filter(abs(?pos1 - ?pos2) + abs(?pos1 - ?pos3) = ?d) 
} 

------------------- 
| p | neighbors | 
=================== 
| :p1 | "p2, p3" | 
| :p2 | "p1, p3" | 
| :p3 | "p2, p4" | 
| :p4 | "p2, p3" | 
-------------------