実行ファイルがWindowsバッチファイルの％PATH％に存在するかどうかをテストするにはどうすればよいですか？

Question

私はWindowsのバッチファイルからPATH環境変数に実行ファイルが存在するかどうかをテストする簡単な方法を探しています。

OSが提供していない外部ツールの使用は許可されていません。必要最小限のWindowsバージョンはWindows XPです。

Answer 1

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X) 
if defined FOUND ... 

あなたが別の拡張のためにこれを必要な場合は、単にPATHEXTを反復：

set FOUND= 
for %%e in (%PATHEXT%) do (
    for %%X in (myExecutable%%e) do (
    if not defined FOUND (
     set FOUND=%%~$PATH:X 
    ) 
) 
) 

ので、whereも従来のWindowsのバージョンにすでに存在しているが、私は1へのアクセスを持っていないということだろう分かりません。

where myExecutable 

をし、それが見つからなかった場合はゼロ以外の終了コードを返します。私のマシン上で以下も動作します。バッチでは、出力をNULにリダイレクトしたいと思うかもしれません。

Answer 2

@echo off 
set found= 
set prog=cmd.exe 
for %%i in (%path%) do if exist %%i\%prog% set found=%%i 
echo "%found%" 
if "%found%"=="" .... 

Answer 3

場合によっては、出力が期待どおりに一致するかどうかを確認するこの単純な解決法が機能することがあります。最初の行はコマンドを実行し、標準出力の最後の行を取得します。

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i 
if "%xcopyoutput%"=="" echo xcopy not in path. 

Answer 4

これは、パラメータ置換によって行うことができます。

%~$PATH:1 

実行可能ファイル名の完全パスを％1に返します。空の文字列を返します。

これはユーザー定義変数では機能しません。したがって、実行可能ファイル名がスクリプトのパラメータでない場合は、サブルーチンが必要です。たとえば：

call :s_which app.exe 
if not "%_path% == "" (
    app.exe 
) 

goto :eof 

:s_which 
    setlocal 
    endlocal & set _path=%~$PATH:1 
    goto :eof 

ここhttp://ss64.com/nt/syntax-args.html

Answer 5

を参照してくださいには、アプリケーションを実行しようとすると、エラーその後を扱うシンプルなソリューションです。

file.exe /? 2> NUL 
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path 

エラーコード9009は、通常、ファイルが見つかりません。

唯一の欠点は、見つかった場合にはfile.exeが実際に実行されていることです（場合によっては、それは望ましくない場合があります）。

Answer 6

Windows Vista以降のバージョンには、パス内のプログラムを検索するwhere.exeというプログラムが付属しています。それはこのように動作します：バッチファイルで使用するためにあなただけのERRORLEVELを設定し、任意の出力を生成しません/qスイッチを使用することができます

D:\>where notepad 
C:\Windows\System32\notepad.exe 
C:\Windows\notepad.exe 

D:\>where where 
C:\Windows\System32\where.exe 

。

where /q myapplication 
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH. 
    EXIT /B 
) ELSE (
    ECHO Application exists. Let's go! 
) 

やメッセージを印刷し、アプリを終了し、簡単な（あまり読み）速記版：

where /q myapplication || ECHO Cound not find app. && EXIT /B 

Answer 7

Useコマンド：

PowerShellのテストパス「あなたが探してexeファイル」

現在の場合はTrueを返し、そうでない場合はFalseを返します。