コンボボックス（VBA）内のユニークなレコードのみ

Question

コンボボックスを持っています。私は一意のレコードだけを必要とし、私はこのページに切り替えるときにそれらを更新したい。そのために 私は、次のコードを使用：

Private Sub MultiPage1_Change() 
Dim Rand As Long 
Dim ws As Worksheet 
Set ws = Worksheets("BD_IR") 
Dim i As Long 
Rand = 3 
Do While ws.Cells(Rand, 3).Value <> "" And Rand < 65536 
    If Me.repereche.ListCount <> 0 Then 
     For i = 0 To (Me.repereche.ListCount) 
     If Me.repereche.List(i, 0) <> Mid(ws.Cells(Rand, 3).Value, 4, 10) Then 
      Me.Controls("repereche").AddItem Mid(ws.Cells(Rand, 3).Value, 4, 10) 
     End If 
     Next i 
    ElseIf Me.repereche.ListCount = 0 Then 
     Me.Controls("repereche").AddItem Mid(ws.Cells(Rand, 3).Value, 4, 10) 
    End If 
    Rand = Rand + 1 
Loop 

このコードの問題は、（問題がどこにあると私は知らないのですか？）私は、ページを変更し、私は戻ってこのページに来たときにということですコンボボックスは...より多くの（ユニークではない）アイテムを追加します。どこが間違っていますか？

Answer 1

は、このコードを試してみてください。

Dim ws As Worksheet 
Dim rCell As Range 

Set ws = Worksheets("BD_IR") 

'//Clear combobox 
repereche.Clear 

With CreateObject("Scripting.Dictionary") 
    For Each rCell In ws.Range("C3", ws.Cells(Rows.Count, "C").End(xlUp)) 
     If Not .exists(rCell.Value) Then 
      .Add rCell.Value, Nothing 
     End If 
    Next rCell 

    repereche.List = .keys 
End With 

あなたは値ではなく、エラーに使用するよりも辞書に存在するかどうかを確認し、一度にコンボボックスにコレクション全体を追加することができますように私は、コレクションの上にこれを好みます。