XSLTで小数点以下をソートする

Question

XMLデータをソートしようとしていますが、私はW3sのチュートリアルに従っていますが、コードがうまくいかないのですか？

<xsl:for-each select="garage/car[colour='red']"> 
    <xsl:apply-templates> 

<xsl:sort select="number(price)" order="descending" data-type="number" /> 
</xsl:apply-templates> 

    <tr>  
    <td><xsl:value-of select="make"/></td> 
    <td><xsl:value-of select="model"/></td> 
    <td><xsl:value-of select="price"/></td> 
    </tr> 


    </xsl:for-each> 

XMLの例〜：

<garage> 
    <car> 
     <make>vw</make> 
     <model>golf</model> 
     <color>red</color> 
     <price>5.99</price> 
    </car> 
    <car> 
     <make>ford</make> 
     <model>focus</model> 
     <color>black</color> 
     <price>3.66</price> 
    </car> 
    <car> 
     <make>honda</make> 
     <model>civic</model> 
     <color>red</color> 
     <price>15.99</price> 
    </car> 
</garage> 

Answer 1

だから、価格降順ですべての赤い車を見せたいですか？

色/色の綴りに一貫している場合は、役立ちます。私はイギリス人で、あなたの痛みを感じます！また

あなたは、各-用および適用・テンプレートを混合している（両方の仕事）を適用し、テンプレート

方法：

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="html" version="1.0" indent="yes" /> 

    <xsl:template match="/"> 
     <xsl:apply-templates select="garage/car[color='red']"> 
     <xsl:sort select="number(price)" order="descending" data-type="number" /> 
     </xsl:apply-templates> 
    </xsl:template> 

    <xsl:template match="car[color='red']"> 
     <tr> 
     <td> 
      <xsl:value-of select="make" /> 
     </td> 
     <td> 
      <xsl:value-of select="model" /> 
     </td> 
     <td> 
      <xsl:value-of select="price" /> 
     </td> 
     </tr> 
    </xsl:template>  
</xsl:stylesheet> 

ため、各方法：

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="html" version="1.0" indent="yes" /> 

    <xsl:template match="/"> 
     <xsl:for-each select="garage/car[color='red']"> 
     <xsl:sort select="number(price)" order="descending" data-type="number" /> 
     <tr> 
      <td> 
       <xsl:value-of select="make" /> 
      </td>  
      <td> 
       <xsl:value-of select="model" /> 
      </td> 
      <td> 
       <xsl:value-of select="price" /> 
      </td> 
     </tr> 
     </xsl:for-each> 
    </xsl:template> 

</xsl:stylesheet>