カスタムシェイダーがAndroidで動作しない

Question

カメラに取り付けられているImage Effectとして、ShadertoyからPlasma ball shaderをUnityに移植しました。これは、エディタとWindowsのスタンドアロンビルドで正常に動作します。 Android搭載端末では動作しません。 Androidで青と黒の画像が点滅しています。ここで

は、ユニティ・エディタとWindowsのビルドで次のようになります。

ここでは、Android上で次のようになります。

移植されたシェーダコード：

Shader "Hidden/Plasma Space Ball Image Effect" 
{ 
    Properties 
    { 
     iChannel0("iChannel0", 2D) = "white" {} 
    //[MaterialToggle] _isToggled("isToggle", Float) = 0 
    } 
     SubShader 
    { 
     // No culling or depth 
     Cull Off ZWrite Off ZTest Always 

     Pass 
     { 
      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 

      #include "UnityCG.cginc" 

      struct appdata 
      { 
       float4 vertex : POSITION; 
       float2 uv : TEXCOORD0; 
      }; 

      struct v2f 
      { 
       float2 uv : TEXCOORD0; 
       float4 vertex : SV_POSITION; 
      }; 

      v2f vert(appdata v) 
      { 
       v2f o; 
       o.vertex = UnityObjectToClipPos(v.vertex); 
       o.uv = v.uv; 
       return o; 
      } 

      sampler2D iChannel0; 

      //Ported from https://www.shadertoy.com/view/MstXzf 

      float3 hb(float2 pos, float t, float time, float2 rot, float size, sampler2D tex0) 
      { 
       float2 newUv = 0.2*(pos/(1.2 - t) + 0.5*time*rot); 
       //float texSample = texture(tex0, newUv).b; 
       float texSample = tex2D(tex0, newUv).b; 
       float uOff = 0.2*(texSample + 0.3*time);  //lsf3RH 
       float2 starUV = newUv + float2(uOff, 0.0); 
       //return float3(0.3, 0.3, 1.0) + 1.3*texture(tex0, starUV).b; 
       return float3(0.3, 0.3, 1.0) + 1.3*tex2D(tex0, starUV).b; 
      } 

      float4 blob(float2 uv, float size, float time, sampler2D tex0) 
      { 
       float2 center = float2(0., 0.); 

       float2 pos = center - uv; 
       float t = length(pos); 
       float st = size - t; 

       float2 rot = 0.005*float2(sin(time/16.), sin(time/12.)); //MslGWN 

       float alpha = smoothstep(0.0, 0.2*size, st); 

       float3 col = hb(pos, t, time, rot, size, tex0); 
       float a1 = smoothstep(-1.4, -1.0, -col.b); 
       col = lerp(col, hb(pos, t, -time, -rot, size, tex0), a1); 

       col += 0.8*exp(-12.*abs(t - 0.8*size)/size); 
       float a2 = smoothstep(-1.4, -1.0, -col.b); 

       alpha -= a2; 

       //float crosshair = float((abs(pos.x) < 0.005 && abs(pos.y) < 0.15) || (abs(pos.y) < 0.005&&abs(pos.x) < 0.15)); 
       //return float4(col, alpha) + crosshair; 

       return float4(col, alpha); 
      } 

      float4 main_(float2 uv, float size) 
      { 
       return blob(uv, size, _Time.y, iChannel0); 
      } 


      fixed4 frag(v2f i) : SV_Target 
      { 
       float4 fragColor = 0; 
       float2 fragCoord = i.vertex.xy; 

       ///--------------------------------------------------- 

       float2 uv = fragCoord.xy/_ScreenParams.xy; 
       float2 cr = uv*2. - 1.; 
       cr.x *= _ScreenParams.x/_ScreenParams.y; 

       //late addition to elaborate background motion, could be reused later on 
       float2 rot = 0.5*float2(sin(_Time.y/16.), sin(_Time.y/12.)); 

       float4 ball = clamp(main_(cr, sin(_Time.y)*0.05 + 0.5 + 0.5), 0., 1.); 
       //float3 bg = float3(0.7, 0.7, 1.0)*texture(iChannel0, uv + rot + 0.1*ball.rb).b; 
       float3 bg = float3(0.7, 0.7, 1.0)*tex2D(iChannel0, uv + rot + 0.1*ball.rb).b; 

       //simulated gl blend 
       fragColor = float4(lerp(bg, ball.rgb, ball.a), 1.0); 
       //fragColor = lerp(fragColor,tex2D(iChannel0, i.uv).rgba,.5); 
       return fragColor; 
      } 
      ENDCG 
     } 
    } 
} 

---

入力スロットhereのiChannel0に使用されている画像は、上記のシェイダーで見つけることができます。

物事は私が試してみた：

• グラフィック設定にシェーダを追加Unityは、ビルドプロセス中に それを含めるようにします。
• Auto Graphics APIを無効にし、OpenGLES2とOpenGLES3を試してみます。
• Androidスタジオでログを確認しています。エラー/警告は一切ありません。

これらのどれも問題を解決していませんでした。

ソフトウェアやデバイス情報という場合に役立ちます：

• ユニティ5.6.0f3
• アンドロイド4.4.2

を私はGLSL、HLSLを勉強していますので、これは、学習や教育目的のために使用されています、CG/shaderlabシェーダ言語。私は、移植されたシェーダがAndroidデバイスで期待通りに動作しない理由を知りたいだけです。

なぜAndroidでは青色と黒色の画像が点滅していますか？

Answer 1

OpenGLES2のフラグメントシェーダの位置にVPOSセマンティクスを使用する必要があります。 Unity docsから
：

フラグメントシェーダは 特別VPOSのセマンティックとしてレンダリングされるピクセルの位置を受信することができます。この機能はシェーダ モデル3.0からのみ存在するため、シェーダは#pragma target 3.0 コンパイルディレクティブを持つ必要があります。

だから、取得するためにスクリーン空間位置：

// note: no SV_POSITION in this struct 
struct v2f { 
    float2 uv : TEXCOORD0; 
}; 

v2f vert (
    float4 vertex : POSITION, // vertex position input 
    float2 uv : TEXCOORD0, // texture coordinate input 
    out float4 outpos : SV_POSITION // clip space position output 
    ) 
{ 
    v2f o; 
    o.uv = uv; 
    outpos = UnityObjectToClipPos(vertex); 
    return o; 
} 

fixed4 frag (v2f i, UNITY_VPOS_TYPE screenPos : VPOS) : SV_Target 
{ 
    // screenPos.xy will contain pixel integer coordinates. 
    float4 fragColor = 0; 
    float2 fragCoord = screenPos; 

しかし、あなたはすでにUVを渡すので、多分あなたがそれらを使用することができますか？

float2 uv = i.uv; 

---

それは私が間違っていたが判明しました。

CGPROGRAM 
#pragma vertex vert 
#pragma fragment frag 

float4 vert (float4 vertex : POSITION) : SV_Position 
{     
    return UnityObjectToClipPos(vertex);     
} 

fixed4 frag (float4 screenPos : SV_Position) : SV_Target 
{ 
    float uvx = screenPos.x/_ScreenParams.x; 
    return float4(uvx, 0., 0., 1.); 
} 
ENDCG 

とライン float uvx = screenPos.x/_ScreenParams.x;がコンパイルされる：（？たぶん誰かがこれを説明することができます）あなたは、私は小さなテストシェーダを作っ

0 ..あなたが得るOpenGLES2におけるフラグメントシェーダでクリップ空間位置を取得いけません
tmpvar_2.x = (0.0/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3

しかし、あなたは
fixed4 frag (float4 screenPos : VPOS) : SV_TargetVPOSセマンティックを使用する場合、同じ行は次のようにコンパイルされるように
tmpvar_2.x = (gl_FragCoord.x/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3

あなたはフラグメントシェーダの画面空間の位置を取得するためにVPOSのセマンティックを使用する必要があるように見えますOpenGLES2のためのようにします。