VB.NETのランダムな整数

Question

単体テストに使用するには、1からn（nは正の整数）の間のランダムな整数を生成する必要があります。真のランダム性を保証するために、あまりに複雑な何かを必要としません。これは昔ながらの乱数です。

どうすればいいですか？

Answer 1

1からNまでの任意の整数値を取得するには、以下を使用します。

CInt(Math.Ceiling(Rnd() * n)) + 1 

Answer 2

Public Function RandomNumber(ByVal n As Integer) As Integer 
    'initialize random number generator 
    Dim r As New Random(System.DateTime.Now.Millisecond) 
    Return r.Next(1, n) 
End Function 

Answer 3

使用System.Random：

Dim MyMin As Integer = 1, MyMax As Integer = 5, My1stRandomNumber As Integer, My2ndRandomNumber As Integer 

' Create a random number generator 
Dim Generator As System.Random = New System.Random() 

' Get a random number >= MyMin and <= MyMax 
My1stRandomNumber = Generator.Next(MyMin, MyMax + 1) ' Note: Next function returns numbers _less than_ max, so pass in max + 1 to include max as a possible value 

' Get another random number (don't create a new generator, use the same one) 
My2ndRandomNumber = Generator.Next(MyMin, MyMax + 1) 

Answer 4

次のようなコードを書くための提案は問題がある、何度も指摘されているとおり：

Public Function GetRandom(ByVal Min As Integer, ByVal Max As Integer) As Integer 
    Dim Generator As System.Random = New System.Random() 
    Return Generator.Next(Min, Max) 
End Function 

理由はということですRandomクラスのコンストラクタは、システムのクロックに基づくデフォルトのシードを提供します。ほとんどのシステムでは、これは粒度が限られています（20 ms付近のどこか）。次のコードを記述するのであれば、あなたは行に同じ数を何回の束を取得するつもりだ：

Dim randoms(1000) As Integer 
For i As Integer = 0 to randoms.Length - 1 
    randoms(i) = GetRandom(1, 100) 
Next 

次のコードはこの問題に対処：

Public Function GetRandom(ByVal Min As Integer, ByVal Max As Integer) As Integer 
    ' by making Generator static, we preserve the same instance ' 
    ' (i.e., do not create new instances with the same seed over and over) ' 
    ' between calls ' 
    Static Generator As System.Random = New System.Random() 
    Return Generator.Next(Min, Max) 
End Function 

は、私が一緒に投げたが1〜100の間で25個のランダムな整数を生成するために、両方の方法を使用して簡単なプログラムは、ここで出力です：

Non-static: 70 Static: 70 
Non-static: 70 Static: 46 
Non-static: 70 Static: 58 
Non-static: 70 Static: 19 
Non-static: 70 Static: 79 
Non-static: 70 Static: 24 
Non-static: 70 Static: 14 
Non-static: 70 Static: 46 
Non-static: 70 Static: 82 
Non-static: 70 Static: 31 
Non-static: 70 Static: 25 
Non-static: 70 Static: 8 
Non-static: 70 Static: 76 
Non-static: 70 Static: 74 
Non-static: 70 Static: 84 
Non-static: 70 Static: 39 
Non-static: 70 Static: 30 
Non-static: 70 Static: 55 
Non-static: 70 Static: 49 
Non-static: 70 Static: 21 
Non-static: 70 Static: 99 
Non-static: 70 Static: 15 
Non-static: 70 Static: 83 
Non-static: 70 Static: 26 
Non-static: 70 Static: 16 
Non-static: 70 Static: 75 

Answer 5

Function xrand() As Long 
     Dim r1 As Long = Now.Day & Now.Month & Now.Year & Now.Hour & Now.Minute & Now.Second & Now.Millisecond 
     Dim RAND As Long = Math.Max(r1, r1 * 2) 
     Return RAND 
End Function 

[BBOYSE] この最善の方法、ゼロから：P

Answer 6

あなたは偉大な答えであるヨセフの答えを使用している場合は、あなたがこれらのバックは次のようにバックアップするために実行します。

dim i = GetRandom(1, 1715) 
dim o = GetRandom(1, 1715) 

その後その結果、コールがすぐに処理されるため、同じ結果が何度も繰り返される可能性があります。これは'08年の問題ではなかったかもしれませんが、今日のプロセッサの方がはるかに高速であるため、システムクロックで2回目の呼び出しを行う前に十分な時間を変更することはできません。

System.Random（）関数はシステムクロックに基づいているため、次の呼び出しの前に変更するのに十分な時間が必要です。これを達成する1つの方法は、現在のスレッドを1ミリ秒間一時停止することです。以下の例を参照してください：

Public Function GetRandom(ByVal min as Integer, ByVal max as Integer) as Integer 
    Static staticRandomGenerator As New System.Random 
    max += 1 
    Return staticRandomGenerator.Next(If(min > max, max, min), If(min > max, min, max)) 
End Function 

Answer 7

をすべての答えは、これまでの問題やバグを持っている（複数、1つだけでなく）。私は説明します。しかし、まず、ダン・タオの洞察に静的変数を使ってジェネレータ変数を覚えておきたいので、何度も同じことを何度も繰り返さないようにしてください。しかし、彼のコードは、私が今説明しているように、ほとんどの人が持っているのと同じ欠陥がありました。

MSはNext（）メソッドをかなり奇妙にしました。 Minパラメータは予想通りの最小値ですが、最大パラメータはで、の排他的ではありません。言い換えると、min = 1とmax = 5を渡すと、乱数は1,2,3、または4のいずれかになりますが、5は含まれません。これは、MicrosoftのRandom.Next（）メソッドを使用するすべてのコードの2つの潜在的なバグのうちの最初のものです。 シンプル答え（まだ他の可能性のあるまれな問題で）、あなたが使用する必要があるだろうについては

：

Private Function GenRandomInt(min As Int32, max As Int32) As Int32 
    Static staticRandomGenerator As New System.Random 
    Return staticRandomGenerator.Next(min, max + 1) 
End Function 

それはそれがより明確になりますので、（私はむしろIntegerよりInt32を使用したいですどのように大きなintがあり、それに加えて入力しますが、自分に合うように短くなっています。）

私はこの方法では2つの潜在的な問題を参照してください、それはほとんどの用途のために）適した（と正しくなります。だからの簡易ソリューションが必要な場合は、これが正しいと思います。

この関数で表示される唯一の2つの問題は次のとおりです。 1：Max = Int32.MaxValueの場合、1を追加すると数値オーバーフローが発生します。 altho、これはまれで、まだ可能性があります。 2：min> max + 1. min = 10かつmax = 5のとき、Next関数はエラーをスローします。これはあなたが望むものかもしれません。それはどちらでもないかもしれません。または、min = 5とmax = 4.を考慮して、1を追加すると5がNextメソッドに渡されますが、実際にエラーが発生してもエラーは発生しませんが、テストしたMicrosoft .NETコードは5です。 max = minのときは、実際には「排他的な」maxではありません。しかし、Random.Next（）関数のmax <分のときは、ArgumentOutOfRangeExceptionがスローされます。 Microsoftの実装は実際には一貫性がなく、この点でもバグです。

あなたは分が> maxはありませんので、エラーがスローされていない場合、単純に数字を交換することもできますが、それは完全に希望されているものに依存します。無効な値でエラーを発生させたい場合は、このコードでMSの排他的な最大値（max + 1）が最小値になったときにエラーをスローする方が良いでしょう。回避策最大= Int32.MaxValueを少し不便ですが、私はこのような状況の両方を処理する徹底した機能を掲示することを期待するときのための取り扱い

。私がそれをコード化したものとは異なる振る舞いをしたいのなら、あなた自身に合ってください。これらの2つの問題に注意してください。

ハッピーコーディング！

編集： だから私は、ランダムな整数ジェネレータを必要とし、私はそれを「正しい」をコーディングすることを決めました。だから誰もが完全な機能を望むなら、ここで実際に動作するものがあります。 （。。しかし、それは、コードのわずか2行で最も単純な賞を獲得していません。しかし、それはどちらか本当に複雑ではありません）

''' <summary> 
''' Generates a random Integer with any (inclusive) minimum or (inclusive) maximum values, with full range of Int32 values. 
''' </summary> 
''' <param name="inMin">Inclusive Minimum value. Lowest possible return value.</param> 
''' <param name="inMax">Inclusive Maximum value. Highest possible return value.</param> 
''' <returns></returns> 
''' <remarks></remarks> 
Private Function GenRandomInt(inMin As Int32, inMax As Int32) As Int32 
    Static staticRandomGenerator As New System.Random 
    If inMin > inMax Then Dim t = inMin : inMin = inMax : inMax = t 
    If inMax < Int32.MaxValue Then Return staticRandomGenerator.Next(inMin, inMax + 1) 
    ' now max = Int32.MaxValue, so we need to work around Microsoft's quirk of an exclusive max parameter. 
    If inMin > Int32.MinValue Then Return staticRandomGenerator.Next(inMin - 1, inMax) + 1 ' okay, this was the easy one. 
    ' now min and max give full range of integer, but Random.Next() does not give us an option for the full range of integer. 
    ' so we need to use Random.NextBytes() to give us 4 random bytes, then convert that to our random int. 
    Dim bytes(3) As Byte ' 4 bytes, 0 to 3 
    staticRandomGenerator.NextBytes(bytes) ' 4 random bytes 
    Return BitConverter.ToInt32(bytes, 0) ' return bytes converted to a random Int32 
End Function 

Answer 8

Dim rnd As Random = New Random 
rnd.Next(n) 

Answer 9

あなたは一度だけ、擬似乱数ジェネレータを作成する必要があります。

整数は、あなたのニーズに十分応えている場合

Dim Generator As System.Random = New System.Random() 

次に、あなたが使用することができます。

Public Function GetRandom(myGenerator As System.Random, ByVal Min As Integer, ByVal Max As Integer) As Integer 
'min is inclusive, max is exclusive (dah!) 
Return myGenerator.Next(Min, Max + 1) 
End Function 

何度でも好きなように。ラッパー関数の使用は、最大値が排他的であるためにのみ正当化されます - 乱数はこのように動作しますが、.Nextの定義は混乱します。ジェネレータを作成

あなたが必要とするたびに番号が私の意見が間違っています。擬似乱数はこのようには機能しません。

まず、あなたは他の回答で議論されてきた初期の問題を取得します。一度初期化すると、この問題は発生しません。

第2に、乱数の有効なシーケンスが得られるとは確信していません。むしろ、コンピュータ時間に基づいて自動的にシードされる複数の異なるシーケンスの最初の数のコレクションを取得します。これらの数字がシーケンスのランダム性を確認するテストに合格することは確かではありません。

Answer 10

マイクロソフト例Rnd Function

https://msdn.microsoft.com/en-us/library/f7s023d2%28v=vs.90%29.aspx

の1-乱数ジェネレータを初期化します。

Randomize() 

2 - ランダムな値を生成する

Dim value As Integer = CInt(Int((6 * Rnd()) + 1)) 

Answer 11

参考まで

、BASICの同じ結果（1980年を与えるべきであるRNDとRANDOMIZE（のためのVB NETのfuctionの定義）と1の間と6すべてのバージョンの後です：

Public NotInheritable Class VBMath 
    ' Methods 
    Private Shared Function GetTimer() As Single 
     Dim now As DateTime = DateTime.Now 
     Return CSng((((((60 * now.Hour) + now.Minute) * 60) + now.Second) + (CDbl(now.Millisecond)/1000))) 
    End Function 

    Public Shared Sub Randomize() 
     Dim timer As Single = VBMath.GetTimer 
     Dim projectData As ProjectData = ProjectData.GetProjectData 
     Dim rndSeed As Integer = projectData.m_rndSeed 
     Dim num3 As Integer = BitConverter.ToInt32(BitConverter.GetBytes(timer), 0) 
     num3 = (((num3 And &HFFFF) Xor (num3 >> &H10)) << 8) 
     rndSeed = ((rndSeed And -16776961) Or num3) 
     projectData.m_rndSeed = rndSeed 
    End Sub 

    Public Shared Sub Randomize(ByVal Number As Double) 
     Dim num2 As Integer 
     Dim projectData As ProjectData = ProjectData.GetProjectData 
     Dim rndSeed As Integer = projectData.m_rndSeed 
     If BitConverter.IsLittleEndian Then 
      num2 = BitConverter.ToInt32(BitConverter.GetBytes(Number), 4) 
     Else 
      num2 = BitConverter.ToInt32(BitConverter.GetBytes(Number), 0) 
     End If 
     num2 = (((num2 And &HFFFF) Xor (num2 >> &H10)) << 8) 
     rndSeed = ((rndSeed And -16776961) Or num2) 
     projectData.m_rndSeed = rndSeed 
    End Sub 

    Public Shared Function Rnd() As Single 
     Return VBMath.Rnd(1!) 
    End Function 

    Public Shared Function Rnd(ByVal Number As Single) As Single 
     Dim projectData As ProjectData = ProjectData.GetProjectData 
     Dim rndSeed As Integer = projectData.m_rndSeed 
     If (Number <> 0) Then 
      If (Number < 0) Then 
       Dim num1 As UInt64 = (BitConverter.ToInt32(BitConverter.GetBytes(Number), 0) And &HFFFFFFFF) 
       rndSeed = CInt(((num1 + (num1 >> &H18)) And CULng(&HFFFFFF))) 
      End If 
      rndSeed = CInt((((rndSeed * &H43FD43FD) + &HC39EC3) And &HFFFFFF)) 
     End If 
     projectData.m_rndSeed = rndSeed 
     Return (CSng(rndSeed)/1.677722E+07!) 
    End Function 

End Class 

ランダムCLASSですが：

Public Class Random 
    ' Methods 
    <__DynamicallyInvokable> _ 
    Public Sub New() 
     Me.New(Environment.TickCount) 
    End Sub 

    <__DynamicallyInvokable> _ 
    Public Sub New(ByVal Seed As Integer) 
     Me.SeedArray = New Integer(&H38 - 1) {} 
     Dim num4 As Integer = If((Seed = -2147483648), &H7FFFFFFF, Math.Abs(Seed)) 
     Dim num2 As Integer = (&H9A4EC86 - num4) 
     Me.SeedArray(&H37) = num2 
     Dim num3 As Integer = 1 
     Dim i As Integer 
     For i = 1 To &H37 - 1 
      Dim index As Integer = ((&H15 * i) Mod &H37) 
      Me.SeedArray(index) = num3 
      num3 = (num2 - num3) 
      If (num3 < 0) Then 
       num3 = (num3 + &H7FFFFFFF) 
      End If 
      num2 = Me.SeedArray(index) 
     Next i 
     Dim j As Integer 
     For j = 1 To 5 - 1 
      Dim k As Integer 
      For k = 1 To &H38 - 1 
       Me.SeedArray(k) = (Me.SeedArray(k) - Me.SeedArray((1 + ((k + 30) Mod &H37)))) 
       If (Me.SeedArray(k) < 0) Then 
        Me.SeedArray(k) = (Me.SeedArray(k) + &H7FFFFFFF) 
       End If 
      Next k 
     Next j 
     Me.inext = 0 
     Me.inextp = &H15 
     Seed = 1 
    End Sub 

    Private Function GetSampleForLargeRange() As Double 
     Dim num As Integer = Me.InternalSample 
     If ((Me.InternalSample Mod 2) = 0) Then 
      num = -num 
     End If 
     Dim num2 As Double = num 
     num2 = (num2 + 2147483646) 
     Return (num2/4294967293) 
    End Function 

    Private Function InternalSample() As Integer 
     Dim inext As Integer = Me.inext 
     Dim inextp As Integer = Me.inextp 
     If (++inext >= &H38) Then 
      inext = 1 
     End If 
     If (++inextp >= &H38) Then 
      inextp = 1 
     End If 
     Dim num As Integer = (Me.SeedArray(inext) - Me.SeedArray(inextp)) 
     If (num = &H7FFFFFFF) Then 
      num -= 1 
     End If 
     If (num < 0) Then 
      num = (num + &H7FFFFFFF) 
     End If 
     Me.SeedArray(inext) = num 
     Me.inext = inext 
     Me.inextp = inextp 
     Return num 
    End Function 

    <__DynamicallyInvokable> _ 
    Public Overridable Function [Next]() As Integer 
     Return Me.InternalSample 
    End Function 

    <__DynamicallyInvokable> _ 
    Public Overridable Function [Next](ByVal maxValue As Integer) As Integer 
     If (maxValue < 0) Then 
      Dim values As Object() = New Object() { "maxValue" } 
      Throw New ArgumentOutOfRangeException("maxValue", Environment.GetResourceString("ArgumentOutOfRange_MustBePositive", values)) 
     End If 
     Return CInt((Me.Sample * maxValue)) 
    End Function 

    <__DynamicallyInvokable> _ 
    Public Overridable Function [Next](ByVal minValue As Integer, ByVal maxValue As Integer) As Integer 
     If (minValue > maxValue) Then 
      Dim values As Object() = New Object() { "minValue", "maxValue" } 
      Throw New ArgumentOutOfRangeException("minValue", Environment.GetResourceString("Argument_MinMaxValue", values)) 
     End If 
     Dim num As Long = (maxValue - minValue) 
     If (num <= &H7FFFFFFF) Then 
      Return (CInt((Me.Sample * num)) + minValue) 
     End If 
     Return (CInt(CLng((Me.GetSampleForLargeRange * num))) + minValue) 
    End Function 

    <__DynamicallyInvokable> _ 
    Public Overridable Sub NextBytes(ByVal buffer As Byte()) 
     If (buffer Is Nothing) Then 
      Throw New ArgumentNullException("buffer") 
     End If 
     Dim i As Integer 
     For i = 0 To buffer.Length - 1 
      buffer(i) = CByte((Me.InternalSample Mod &H100)) 
     Next i 
    End Sub 

    <__DynamicallyInvokable> _ 
    Public Overridable Function NextDouble() As Double 
     Return Me.Sample 
    End Function 

    <__DynamicallyInvokable> _ 
    Protected Overridable Function Sample() As Double 
     Return (Me.InternalSample * 4.6566128752457969E-10) 
    End Function 


    ' Fields 
    Private inext As Integer 
    Private inextp As Integer 
    Private Const MBIG As Integer = &H7FFFFFFF 
    Private Const MSEED As Integer = &H9A4EC86 
    Private Const MZ As Integer = 0 
    Private SeedArray As Integer() 
End Class