SASデータステップを使用してファイルをエクスポートするときに列名が見つからない

Question

私はさまざまな国から収集されたデータを含む大きなSASデータセットraw_dataを持っています。このデータセットには、観測が開始された国を列挙する「国」という列があります。 raw_dataに各国の別の.csvファイルをエクスポートしたいと思います。私は、出力を生成するには、次のデータのステップを使用しない：

data _null_; 
    set raw_data; 
    length fv $ 200; 
    fv = "/directory/" || strip(put(country,$32.)) || ".csv"; 
    file write filevar=fv dsd dlm=','; 
    put (_all_) (:); 
run; 

しかし、結果の.csvファイルは、もはやraw_dataから列名を持っています。私は自分のデータセットに100以上のカラムを持っているので、すべてのカラム名をリストアップするのは禁物です。誰も私に上記のコードを変更してエクスポートする.csvファイルに列名を付けるためのガイダンスを私に提供できますか？どんな助けもありがとう！

Answer 1

変数名を保持するマクロ変数を作成して、それらをCSVファイルに格納することができます。

proc sql noprint; 
select name into :var_list separated by ", " 
from sashelp.vcolumn 
where libname="WORK" and memname='RAW_DATA' 
order by varnum; 
quit; 

data _null_; 
set raw_data; 
length fv $ 200; 
by country; 
fv = "/directory/" || strip(put(country,$32.)) || ".csv"; 

if first.country then do; 
    put "&var_list"; 
end; 

file write filevar=fv dsd dlm=','; 
put (_all_) (:); 
run; 

Answer 2

プログラムと非常によく似たこのデータステップを検討してください。 VNEXTを使用してPDVを照会し、各ファイルの最初のレコードとして変数名を書き込みます。

proc sort data=sashelp.class out=class; 
    by age; 
    run; 
data _null_; 
    set class; 
    by age; 
    filevar=catx('\','C:\Users\name\Documents',catx('.',age,'csv')); 
    file dummy filevar=filevar ls=256 dsd; 
    if first.age then link names; 
    put (_all_)(:); 
    return; 
names: 
    length _name_ $32; 
    call missing(_name_); 
    do while(1); 
     call vnext(_name_); 
    if _name_ eq: 'FIRST.' then leave; 
     put _name_ @; 
    end; 
    put; 
    run;