関数型のApplicativeとMonadのインスタンス？

Question

以下のようなデータ型がBlahですが、のタイプのため、Functor、Applicative、Monadを自動的に派生できないため、です。だから私は手動で行う必要がありますが、私はどのようにわからない。私は((->) a)のインスタンスからインスピレーションを得ようとしましたが、私はMonadのインスタンスを理解できません。

newtype Blah a = Blah (String -> a) -- deriving (Functor, Applicative, Monad) 

-- this seems right 
instance Functor Blah where 
    fmap f (Blah g) = Blah (f . g) 

instance Applicative Blah where 
    pure = Blah . const 
    -- This is right, right? 
    (<*>) (Blah f) (Blah g) = Blah $ \x -> f x (g x) 

instance Monad Blah where 
    return = pure 

    -- I'm not having any luck here. 
    (>>=) a b = Blah $ \c -> _ 

編集：誰かがこれを別のものと重複してマークしましたが、私はその回答をどこから得るのか分かりません。 newtypeラッパーは、これを困難にしました。私は(->) aの前にMonadのインスタンスを調べましたが、私はこの質問を書いていましたが、答えの体操は私が必要なものです。

Answer 1

どの程度

Blah f >>= g = Blah $ \s -> 
    let Blah h = g $ f s in h s 

Answer 2

これらのインスタンスはderiveです。 GeneralizedNewtypeDerivingフラグをオンにするだけで、GHCはラップされたタイプのインスタンスを単純に再利用できます。

{-# LANGUAGE GeneralizedNewtypeDeriving #-} 

newtype Blah a = Blah (String -> a) deriving (Functor, Applicative, Monad) 

Answer 3

は、ここでは、型指定された穴を使用して、この自分自身を導くことができる方法です。あなたのコードから始めて、少し名前を変更：

instance Monad Blah where 
    return = pure 
    f >>= g = Blah $ \s -> _ 

あなたはこのようなメッセージが表示されます：

Found hole ‘_’ with type: b 
Relevant bindings include 
    s :: String 
    g :: a -> Blah b 
    f :: Blah a 

だから我々はBlah a、String与えられ、bを生成する必要がある、とa -> Blah b 。まあ、我々はすでにパターンマッチングとBlahに関数を適用することによって、Blah aとStringからaを生成する方法を知っている：

Blah f >>= g = Blah $ \s -> let h = f s in _ 
------      ----------- 

は今我々が得る：

Found hole ‘_’ with type: b 
Relevant bindings include 
    h :: a 
    s :: String 
    g :: a -> Blah b 
    f :: String -> a 

だから我々は持っています我々はBlah bを取得するためにgに与えることができますa、及びその上のパターンマッチングは私たちにString -> bを与える：

Blah f >>= g = Blah $ \s -> let Blah h = g (f s) in _ 
           ---------------- 

今我々が得る：

Found hole ‘_’ with type: b 
Relevant bindings include 
    h :: String -> b 
    s :: String 
    g :: a -> Blah b 
    f :: String -> a 

だから我々はbを必要とし、我々はStringとString -> bを持っています。それは簡単です：

Blah f >>= g = Blah $ \s -> let Blah h = g (f s) in h s 
                --- 

あなたが行く、正しい実装は、種類によって導かれます。 Blahを「実行」するヘルパー関数を定義すると、より明確になる場合があります。

newtype Blah a = Blah { runBlah :: String -> a } 
-- or: 
runBlah :: Blah a -> String -> a 
runBlah (Blah f) = f 

instance Monad Blah where 
    f >>= g = Blah $ \s -> runBlah (g (runBlah f s)) s