Excelファイルを開き、別のCSVファイルにワークシートを保存するVBAマクロ

Question

VBAを初めて使用しました。私は、別の場所から既存のファイルを開き、ワークシート名（タブ名）の名前で各ワークシートを異なるCSVファイルに保存するという要件があります。私はこのようなことを試みました。

Sub SplitFile() 
Dim vPath As String 
vPath = Application.ActiveWorkbook.Path 
Application.ScreenUpdating = False 
Application.DisplayAlerts = False 
For Each xWs In ThisWorkbook.Sheets 
    xWs.Copy 
    Application.ActiveWorkbook.SaveAs Filename:=vPath & "\" & xWs.Name & ".csv", FileFormat:=xlCSV, CreateBackup:=False 
    Application.ActiveWorkbook.Close False 
Next 
Application.DisplayAlerts = True 
Application.ScreenUpdating = True 
End Sub 

これは現在アクティブなワークシートで機能しますが、別のワークシートを別のパスで処理したいと考えています。

ファイルパスを保持する変数を割り当てようとしましたが、エラーがスローされました。

私を助けてください。前もって感謝します。

Answer 1

ブックの変数を作成して、ブックオブジェクトを割り当てる必要があります：

Sub SplitFile() 

Dim vPath As String 
Dim wb As Workbook 
Dim wbPath As Variant 

wbPath = Application.GetOpenFileName("Excel Files (*.xls*), *.xls*") 

If wbPath = False Then Exit Sub 

Set wb = Workbooks.Open(wbPath) 

vPath = wb.Path 
Application.ScreenUpdating = False 
Application.DisplayAlerts = False 
For Each xWs In wb.Sheets 
    xWs.Copy 
    Application.ActiveWorkbook.SaveAs Filename:=vPath & "\" & xWs.Name & ".csv", FileFormat:=xlCSV, CreateBackup:=False 
    Application.ActiveWorkbook.Close False 
Next 
Application.DisplayAlerts = True 
Application.ScreenUpdating = True 
End Sub 

あなたが見ることができるように、あなたはあなたのワークブックを割り当てた後、必要に応じてどこにあなたは自分のコード内でそれに参照してください。