異なるエージェントからエージェントセットを追加してレットにする

Question

私のモデルは、リンクで相互に接続されたエージェントのネットワークです。 エージェントとそのネイバーのネイバーからエージェントセットを作成しようとします（これには異なる値を割り当てる必要があります）。

しかし、私はそれにエージェントセットを含むletを作成します。エージェントはこのエージェントセットをすべて独自のものにするように求めましたが、これは今のところとても良いことです。しかし、元のエージェントが2番目のラインの隣人に尋ねると、2番目のすべての隣人のエージェントセットの代わりに、この隣人のエージェントセットが返されます。 隣人が自分の隣人をすべてそのセット内の異なるエージェントの隣人。

turtleset current-agentset new-agentsetはletで可変とすることができないので、私は単純に行うことができません。だから、普通はset second-neighbors (turtle-set second-neighbors other-nieghborsであるコードは、すでにレットに2番目の隣人に聞くことができないので、うまくいきません。

私はこのことをエージェント固有のものにすることもできません。

は、私が持っているコードは、これまでのように私がしたいことは、彼らが今のようにagentset内のすべてのエージェントがそのリンクの隣人を報告cがあり、この

ask companies [ 
     let this-company self 
     let b link-neighbors 
     ask b [ let c link-neighbors with [self != this-company] 

      ask c [ let d link-neighbors with [not member? self b] 
      ask this-company [ 
       set iburen b 
       set iiburen c 
       set iiiburen d 
     ] 
     ] 
    ] 
    ] 

のように見えます。しかし、これらのリンク - ネイバーを、c内のすべてのエージェントのすべてのリンク - ネイバーを持つ新しいエージェントセットに保管してください。簡単なように私は私+ 1が、私はモデルを実行した場合turtle-set (what I have) (what is new from the next agent asked)

よりも、同じことがD

のために行く、今の薬剤は異なるagentsetほぼすべてのダニを報告しています。彼らは、これらのエージェントをすべて組み合わせるのではなく、いずれかのエージェントから1つのエージェントセットを選択するだけです。ここで

Answer 1

は、私はあなたが必要だと思うものです：

extensions [ nw ] 
breed [ companies company ] 
companies-own [ 
    buren ; a list of agentsets, with one item for each "level" of neighbors 
] 

to setup 
    clear-all 
    ; create a random network and lay it out: 
    create-companies 20 [ create-links-with n-of 3 other companies ] 
    repeat 30 [ layout-spring turtles links 0.2 5 1 ] 

    let num-levels 3 

    ask companies [ 
    let all-neighbors other nw:turtles-in-radius num-levels  
    set buren (list) ; initialize to empty list 
    foreach range num-levels [ i -> 
     let neighbors-at-this-level all-neighbors with [ 
     nw:distance-to myself = i + 1 
     ] 
     set buren lput neighbors-at-this-level buren 
    ] 
    ] 

    ; demonstrate how to access the levels (sorted only for display purposes) 
    ask one-of companies [ 
    show sort item 0 buren ; first level neighbors 
    show sort item 1 buren ; second level neighbors 
    show sort item 2 buren ; third level neighbors 
    ] 

end 

それはレベルごとに一度、すべてのネイバーのリストを通過するので、これは、可能最も効率的なコードではないかもしれませんが、あなたは持っていない限り巨大なネットワーク、あなたは気づくべきではありません。

あなたが本当にiburen、iiburenとiiiburenような変数を使用したい場合、あなたは常にリストの項目のエイリアスができます

set iburen item 0 buren 
set iiburen item 1 buren 
set iiiburen item 2 buren 

...しかし、私はそれをお勧めしません。あなたのエージェントセットをリストに入れれば、より一般的な方法でレベルを考えるように促すはずです。