SPARQLのクエリとしてのリテラルCONSTRUCTクエリ

Question

正しい形式を生成する正しいSPARQLクエリを作成するのに苦労しているので、Protegeを開くことができます。私たちのオントロジはカクテルに関するもので、材料（dbp:ingredients）とレシピ（dbp:prep）を含め、データベースにDBPediaのカクテルをすべて載せたいと考えています。データベースでカクテルを入手するのはうまくいくが、成分とレシピはうまくいかない。 ？？私は今、次のクエリがあります。今宣言されていない

CONSTRUCT {?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients. 
?drink rdf:type owl:NamedIndividual . 
?category rdf:type owl:Class. 
dct:subject rdf:type owl:ObjectProperty. 
dbp:prep rdf:type owl:ObjectProperty. 
dbp:ingredient rdf:type owl:Objectproperty. 
} 
WHERE { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients.} 

ので、食材やレシピを、それが門徒における個人]タブに表示されません。私は、クエリの構築物の部分にこれを追加するときしかし：

?recipe rdf:type owl:NamedIndividual. 
?ingredients rdf:type owl:NamedIndividual. 

私はエラーを取得する：

Virtuoso RDF01 Error Bad variable value in CONSTRUCT: "*5 cL vodka *10 cL orange juice" (tag 246 box flags 0) is not a valid subject, only object of a triple can be a literal

DBpediaの上の準備や食材は単なる文字列、なしリンクされたデータですので、私は思います。 しかし、Protegeでこの作業を行うにはどうしたらいいですか？

Answer 1

RDFトリプルの主題としてリテラルを使用することはできません。代わりに、レシピと食材のリソースを作成し、文字列値をrdfs:comment（または多分rdfs:label）とすることが回避策になります。これは次のように機能します。

CONSTRUCT { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients. 
?drink rdf:type owl:NamedIndividual . 
?category rdf:type owl:Class. 
dct:subject rdf:type owl:ObjectProperty. 
dbp:prep rdf:type owl:ObjectProperty. 
dbp:ingredients rdf:type owl:Objectproperty. 
# add string values as rdfs:comment 
?recipe rdfs:comment ?recipe_str . 
?ingredients rdfs:comment ?ingredients_str 
} 
WHERE { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe_str. 
?drink dbp:ingredients ?ingredients_str. 
BIND(URI(CONCAT("http://dbpedia.org/resource/recipe", MD5(STR(?recipe_str)))) as ?recipe) 
BIND(URI(CONCAT("http://dbpedia.org/resource/ingredients", MD5(STR(?ingredients_str)))) as ?ingredients) 
} 

レシピ（原料）がすでにリソースである場合は、どういうわけか失敗します。 DBpediaではdbp:prepとdbp:ingredientsはDBpediaでは保持されませんが、確かにわからない場合は、実際にリソースとリテラルの両方を許可するrdf:Propertyがあります。 IF-ELSE構文を使用して：

BIND(IF(isLiteral(?recipe_str), URI(CONCAT("http://dbpedia.org/resource/recipe", MD5(STR(?recipe_str)))), ?recipe_str) as ?recipe) 
BIND(IF(isLiteral(?ingredients_str), URI(CONCAT("http://dbpedia.org/resource/ingredients", MD5(STR(?ingredients_str)))), ?ingredients_str) as ?ingredients) 

とあなたも...確かに、その後rdfs:commentトリプルを省略する要するに