バッチ内の値セットを削除する

Question

ネットワーク上のどのマシンがオンラインでオフラインであるかを示すスクリプトを作成しようとしています。

現在、私はオンライン変数/オフライン状態を表示しており、PC名をテキストファイルから入力変数として設定しています。

私がこれまで持っているコードは次のとおりです。マシンがオンラインになったら、私は起こるしたい何

@echo off 
setlocal EnableDelayedExpansion 

for /F "tokens=*" %%a in (VC.txt) do call :append %%a 

:ping 
for %%i in (%VC) do (
ping %%1 -n 1 >nul 
call :test %%i 
) 
echo. 
goto :ping 

:test 
IF %ERRORLEVEL% EQU 0 (
echo Pinging %1 
) else (
echo Off %1 
) 
goto :eof 

:append 
if defined VC (
set VC=%VC% %1 
) else (
set VC=%1 
) 

は、リストから削除するには、です。基本的には、オフラインマシンのリストだけを表示します。 セット全体を拭き取り、新鮮なものにすることなく、これは可能ですか？

Answer 1

このMODは、あなたがやりたいこと：

:test 
IF %ERRORLEVEL% EQU 0 (
echo Pinging %1 
REM Remove this machine from the list 
set "VC=!VC: %1=!" 
) else (
echo Off %1 
) 
goto :eof 

しかし、あなたはあなたのコード内のカップル小さな誤差を持っています。これは固定セクションです：

:ping 
for %%i in (%VC%) do (
ping %%i -n 1 >nul 
call :test %%i 
) 
echo. 
goto :ping 

あなたの問題に関係しないカップルポイントです。マシン名が空白のない単一の単語である場合、forコマンドの"tokens=*"部分は必要ありません。また、callとサブルーチンのすべてがコードを複雑にするだけです。これは私がこれを行う方法です：

@echo off 
setlocal EnableDelayedExpansion 

set "VC=" 
for /F %%a in (VC.txt) do set "VC=!VC! %%a" 

:ping 
for %%i in (%VC%) do (
    ping %%i -n 1 >nul 
    IF !ERRORLEVEL! EQU 0 (
     echo Pinging %%i 
     REM Remove this machine from the list 
     set "VC=!VC: %%i=!" 
    ) else (
     echo Off %%i 
    ) 
) 
echo/ 
if defined VC goto :ping 

echo All machines are on line