Inno Setup Pascal Scriptで文字列の幅と高さを取得

Question

Pascal Scriptで文字列の幅と高さを取得できますか？

例：ここでは

var 
    S: String; 

S := 'ThisIsMyStringToBeChecked' 

私は、現在のフォントサイズやフォントに応じてその高さと幅を返す必要があります。

私はHow to get TextWidth of string (without Canvas)?を読みましたが、Inno Setup Pascalコードに変換することはできません。

私はそのキャプションの文字列の幅がTLabel.Widthを超えた場合、この測定（幅と高さ）clRedで'Too Long To Display'ようTLabel.Captionを変更したいです。

ありがとうございます。

Answer 1

TNewStaticText（ないTLabel）のために、次の作品：

type 
    TSize = record 
    cx, cy: Integer; 
    end; 

function GetTextExtentPoint32(hdc: THandle; s: string; c: Integer; 
    var Size: TSize): Boolean; 
    external 'GetTextExtentPoint32W@Gdi32.dll stdcall'; 
function GetDC(hWnd: THandle): THandle; 
    external 'GetDC@User32.dll stdcall'; 
function SelectObject(hdc: THandle; hgdiobj: THandle): THandle; 
    external 'SelectObject@Gdi32.dll stdcall'; 

procedure SmartSetCaption(L: TNewStaticText; Caption: string); 
var 
    hdc: THandle; 
    Size: TSize; 
    OldFont: THandle; 
begin 
    hdc := GetDC(L.Handle); 
    OldFont := SelectObject(hdc, L.Font.Handle); 
    GetTextExtentPoint32(hdc, Caption, Length(Caption), Size); 
    SelectObject(hdc, OldFont); 

    if Size.cx > L.Width then 
    begin 
    L.Font.Color := clRed; 
    L.Caption := 'Too long to display'; 
    end 
    else 
    begin 
    L.ParentFont := True; 
    L.Caption := Caption; 
    end; 
end;