Common Lispでビットベクトルからストリームを取得する方法は？

Question

私はビットベクトルを持っています - #*10010010001001...

私はREAD-BYTEを使ってベクトルからオクテットを読みたいと思います。 しかし、バイナリストリームオブジェクトが必要です。

私はこれを行う方法を理解できないようです。私は（ビットベクトルから変換）、単純なベクトルから新たなストリームを取得するために、WRITE-SEQUENCEを使用してみました：

(WRITE-SEQUENCE (map 'array #'identity #*10010010...) *standard-output*) 

が、それはCHARACTERする必要が予想されるタイプについて不平を言います。

（私はClozure Common Lispのを使用しています。）

私が間違って何をしているのですか？

（答えとしてフレキシストリームを示唆しないでください。私はただ一つの小さなもののために全く新しいライブラリを追加する予定はありません。）

Answer 1

あなたは非標準のグレーストリーム拡張子を使用することができます独自のストリームクラスを定義します。オクテットベクトルのための簡単な例（私はSBCLを使用していますが、CCLはあまりにも灰色のストリームをサポートする必要があります）：

(deftype octet() '(unsigned-byte 8)) 

(defclass octet-input-stream (fundamental-binary-input-stream) 
    ((data :initarg :data :type (vector octet)) 
    (position :initform 0))) 

(defmethod stream-element-type ((stream octet-input-stream)) 
    'octet) 

(defmethod stream-read-byte ((stream octet-input-stream)) 
    (with-slots (data position) stream 
    (if (< position (length data)) 
     (prog1 (aref data position) 
      (incf position)) 
     :eof))) 

(let* ((arr (make-array 3 :element-type 'octet :initial-contents '(50 100 150))) 
     (stream (make-instance 'octet-input-stream :data arr))) 
    (loop for octet = (read-byte stream nil nil) 
     while octet 
     do (format t "~8,'0b~%" octet))) 
; 00110010 
; 01100100 
; 10010110 

ビットをマスクする必要についてコメントに関しては、bit-wise operatorsが標準です。オクテットベクトルの表示表現のために

(logior 50 #b00001000) 
;=> 58 

、あなた自身のかなりのプリンタディスパッチ関数を定義することができます。

(defun print-octets (stream vector) 
    (write-string "#<octet vector:" stream) 
    (pprint-newline :mandatory stream) 
    (loop for octet across vector 
     do (format stream "~8,'0b " octet) 
      (pprint-newline :fill stream)) 
    (pprint-newline :mandatory stream) 
    (write-string ">" stream)) 


CL-USER> (set-pprint-dispatch '(vector (unsigned-byte 8)) #'print-octets) 
CL-USER> (make-array 20 :element-type 'octet :initial-contents '(54 123 67 34 65 65 23 98 
                   67 23 54 12 76 123 230 65 
                   23 87 49 10)) 
#<octet vector: 
00110110 01111011 01000011 00100010 01000001 01000001 00010111 01100010 
01000011 00010111 00110110 00001100 01001100 01111011 11100110 01000001 
00010111 01010111 00110001 00001010 
>