別のシートに条件を満たすVBAコピー行

Question

VBAを初めて使用しています...この行の最初のセルにXと表示されている場合は、Sheet2からSheet1に行をコピーします。基準。 If条件にエラーがあります...修正方法がわかりません。

Sub LastRowInOneColumn() 
'Find the last used row in a Column: column A in this example 
    Worksheets("Sheet2").Activate 
    Dim LastRow As Long 
    With ActiveSheet 
     LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row 
    End With 
    MsgBox (LastRow) 
    For i = 1 To LastRow 
    If Worksheet.Cells(i, 1).Value = "X" Then 
    ActiveSheet.Row.Value.Copy _ 
    Destination:=Hoja1 
    End If 
    Next i 
End Sub 

Answer 1

ワークセットを指定する必要があります。変更ライン

If Worksheet.Cells(i, 1).Value = "X" Then 

If Worksheets("Sheet2").Cells(i, 1).Value = "X" Then 

にUPD：

は、次のコードを使用してみてください（それが最善のアプローチではありません@SiddharthRoutがAutofilterの使用について検討し、示唆したように。）：

Sub LastRowInOneColumn() 
    Dim LastRow As Long 
    Dim i As Long, j As Long 

    'Find the last used row in a Column: column A in this example 
    With Worksheets("Sheet2") 
     LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row 
    End With 

    MsgBox (LastRow) 
    'first row number where you need to paste values in Sheet1' 
    With Worksheets("Sheet1") 
     j = .Cells(.Rows.Count, "A").End(xlUp).Row + 1 
    End With 

    For i = 1 To LastRow 
     With Worksheets("Sheet2") 
      If .Cells(i, 1).Value = "X" Then 
       .Rows(i).Copy Destination:=Worksheets("Sheet1").Range("A" & j) 
       j = j + 1 
      End If 
     End With 
    Next i 
End Sub 

Answer 2

フォーマット後前回の自分のコードへの回答では、AutoFilterで返された値を別のシートに貼り付けようとすると、必要なすべてのデータを効率的にコピーする方法が見つかりました。このブロックで

With .Range("A1:A" & LastRow) 
    .Autofilter Field:=1, Criteria1:="=*" & strSearch & "*" 
    .Offset(1,0).SpecialCells(xlCellTypeVisible).Cells.Copy 
    Sheets("Sheet2").activate 
    DestinationRange.PasteSpecial 
End With 

、AutoFilterはstrSearchの値を含むすべての行を検索し、他のすべての値を除外。次に、セルをコピーし（ヘッダーがある場合はオフセットを使用）、宛先シートを開き、宛先シートの指定された範囲に値を貼り付けます。