別のパッケージに変数を設定する

Question

別のパッケージで選択した名前の変数を設定したいと思います。どうやってこれを簡単にすることができますか？

ような何か：あなたはそれを行うことができます

$variable_name = 'x'; 
$package::$variable_name = '0'; 
# now $package::x should be == '0' 

Answer 1

$variable_nameが検証された、あなたができることを考える：

eval "\$package::$variable_name = '0'"; 

Answer 2

に、しかし、あなたがそうのような狭窄を無効にする必要があります：

package Test; 

    package main; 

    use strict; 

    my $var_name = 'test'; 
    my $package = 'Test'; 

    no strict 'refs'; 
    ${"${package}::$var_name"} = 1; 

print $Test::test; 

だから私はそれをお勧めしないと思います。ハッシュを使う方が良い。

Answer 3

use 5.010; 
use strict; 
use warnings; 

{ 
    no warnings 'once'; 
    $A::B::C::D = 5; # a test subject 
} 

my $pkg = 'A::B::C'; 
my $var = 'D'; 

# tearing down the walls (no warranty for you): 
    say eval '$'.$pkg."::$var"; # 5 

# tearing down the walls but at least feeling bad about it: 
    say ${eval '\$'.$pkg."::$var" or die $@}; # 5 

# entering your house with a key (but still carrying a bomb): 
    say ${eval "package $pkg; *$var" or die $@}; # 5 

# using `Symbol`:  
    use Symbol 'qualify_to_ref'; 
    say $${ qualify_to_ref $pkg.'::'.$var }; # 5 

# letting us know you plan mild shenanigans 
# of all of the methods here, this one is best 
{ 
    no strict 'refs'; 
    say ${$pkg.'::'.$var}; # 5 
} 

と、次は、あなたに意味をなすのパーティーの場合：

# with a recursive function: 
    sub lookup { 
     @_ == 2 or unshift @_, \%::; 
     my ($head, $tail) = $_[1] =~ /^([^:]+:*)(.*)$/; 
     length $tail 
      ? lookup($_[0]{$head}, $tail) 
      : $_[0]{$head} 
    } 
    say ${ lookup $pkg.'::'.$var }; # 5 

# as a reduction of the symbol table: 
    use List::Util 'reduce'; 
    our ($a, $b); 

    say ${+ reduce {$$a{$b}} \%::, split /(?<=::)/ => $pkg.'::'.$var }; # 5 

そしてもちろん、あなたがに割り当てることができますこれらの方法のいずれかをsayの代わりに使用してください。