Oracleパイプライン関数

Question

FROM句で使用できるオブジェクトを返す関数を作成しようとしています。オラクルのドキュメントに関する調査によると、私はPIPELINED関数が必要であることを発見しました。

私はこのコードを持っている：

CREATE TYPE type_struct AS OBJECT 
(
    i NUMBER 
); 

CREATE TYPE tp_struct AS TABLE OF type_struct; 

CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER) 
RETURN tp_struct PIPELINED 
IS 
    rec type_struct; 
    counter NUMBER; 
BEGIN 
    counter := na; 

    WHILE (counter <= nb) 
    LOOP 
     SELECT counter 
     INTO rec 
     FROM dual; 

     counter := counter + 1; 

     PIPE ROW (rec); 
    END LOOP; 

    RETURN; 
END gen_nums; 
/

意図した結果が包括的の両方、「NB」から「NA」からレコードを持つテーブルです。

機能をコンパイルするとき、私はこのエラーを取得するしかし：

ORAは、UDTを期待00932一貫性のないデータ型は数

Answer 1

ORA 00932 inconsistent datatypes expected udt got number

あなたはこれを取得しまったので、あなたのコードはスカラーを出力に割り当てますタイプ。代入先と一致するように変数をキャストする必要があります。したがって：

SELECT type_struct(counter) 
    INTO rec 
    FROM dual; 

必ずしもパイプライン機能は必要ありません。 table()にはコレクションを返す関数を使用できます。

ここでは、はるかに単純な実装であり、1つのUDTしか必要ありません。

CREATE TYPE tp_numbers AS TABLE OF number; 
/
CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER) 
RETURN tp_numbers 
IS 
    return_value tp_numbers ; 
BEGIN 
    SELECT (na + level) - 1 
    bulk collect INTO return_value 
    FROM dual 
    connect by level <= nb; 

    RETURN return_value ; 
END gen_nums; 
/

Answer 2

CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER) 
RETURN sys.DBMS_DEBUG_VC2COLL PIPELINED --sys.DBMS_DEBUG_VC2COLL an oracle provided collection type. 
IS 
    counter NUMBER; 
BEGIN 
    counter := na; 
    WHILE (counter <= nb) 
    LOOP 
     PIPE ROW (counter); 
     counter := counter + 1; 
    END LOOP; 
    RETURN; 
END gen_nums;