指定されたディレクトリのすべてのファイルとフォルダをループして削除する

Question

指定したディレクトリのすべてのファイルとフォルダをループして削除しようとしています。私は、バッチスクリプトと非常に以前の経験を持っていないと私はオンライン研究のかなりを行っている次が動作しない理由は、しかし、私は理解することはできません。

@echo off 
CLS 
mode con: cols=160 lines=60 
echo. 
::**************************************************************** 
Set  Location[0]=\lib\Debug 
Set  Location[1]=\temp\ 
::**************************************************************** 

:BEGIN 
echo start 

for /F "tokens=2 delims==" %%s in ('set Location[') do (
    for /r %%i in (%%s) do echo %%i 
) 


echo end 
pause 

それがすべて一覧表示されて何が起こって終わりますバッチスクリプトの現在のディレクトリにあるファイル。

このスクリプトをLocation変数で指定されたすべてのディレクトリにループさせ、そこで見つかったすべてのファイルとフォルダを削除するにはどうすればよいですか。クリーンスレート。

Answer 1

これは基本的にありませんが、ベースフォルダを削除されます再作成します。

@echo off 

Set Location[0]=lib\Debug 
Set Location[1]=temp 

for /F "tokens=2 delims==" %%H in ('set Location[') do (
    rmdir /Q /S "%%H" 
    md "%%H" 
) 

ここでは、バッチファイルを実行する前の私のディレクトリ構造の一覧を示します。

C:\BatchFiles\SO\rmdir>dir /b /s 
C:\BatchFiles\SO\rmdir\cleanup.bat 
C:\BatchFiles\SO\rmdir\lib 
C:\BatchFiles\SO\rmdir\temp 
C:\BatchFiles\SO\rmdir\lib\Debug 
C:\BatchFiles\SO\rmdir\lib\donotdelete 
C:\BatchFiles\SO\rmdir\lib\donotdelete.txt 
C:\BatchFiles\SO\rmdir\lib\Debug\deleteme 
C:\BatchFiles\SO\rmdir\lib\Debug\deleteme.txt 
C:\BatchFiles\SO\rmdir\lib\Debug\deleteme\deleteme.txt 
C:\BatchFiles\SO\rmdir\lib\donotdelete\donotdelete.txt 
C:\BatchFiles\SO\rmdir\temp\deleteme 
C:\BatchFiles\SO\rmdir\temp\deleteme.txt 
C:\BatchFiles\SO\rmdir\temp\deleteme\deleteme.txt 

ここで、バッチファイルを実行して、ディレクトリリストを再度実行します。あなたは、一時的なものからデバッグまでのすべてを削除するが、それ以外のものはすべて残しているのがわかる。

C:\BatchFiles\SO\rmdir>cleanup.bat 

C:\BatchFiles\SO\rmdir>dir /b /s 
C:\BatchFiles\SO\rmdir\cleanup.bat 
C:\BatchFiles\SO\rmdir\lib 
C:\BatchFiles\SO\rmdir\temp 
C:\BatchFiles\SO\rmdir\lib\Debug 
C:\BatchFiles\SO\rmdir\lib\donotdelete 
C:\BatchFiles\SO\rmdir\lib\donotdelete.txt 
C:\BatchFiles\SO\rmdir\lib\donotdelete\donotdelete.txt 

Answer 2

これがあなたを助けている場合を参照してください：

@Echo Off 
Set "Location[0]=C:\temp\lib\Debug" 
Set "Location[1]=C:\temp\temp" 

For /F "Tokens=1* Delims==" %%A In ('Set Location[') Do (
    For /R "%%B" %%C In (*.*) Do Echo=%%C) 

pause 

Answer 3

削除し、フォルダをハードコーディングしたい場合、あなたはこのようにそれを行うことができます。

@echo off & setlocal 
set todelete="lib\debug" "temp" "something else" "and this\folder\here" 
call :dodelete %todelete% 
goto :eof 

:dodelete 
if "%~1"=="" goto :eof 
rd /s "%~dp0%~1" 
md "%~dp0%~1" 
shift 
goto :dodelete