EnumWindowsコールバック関数の使用方法は？

Question

私はデスクトップウィンドウへのハンドルを返す単一のきちんとした（閉じた、自己完結型の）関数（GetDesktopHandleと呼ぶ）を持っていたいと思います。私は以下のコードを使用します。しかし、それはDeskHandleでのみ動作し、グローバル変数です。

このグローバル変数を削除するにはどうすればよいですか？私はそれをローカルにする場合は、私がDeskHandleしようとすると、私はgetDesktopWndでAVを得る：= hChild

VAR DeskHandle : HWND; 

function GetDesktopHandle: HWND; 

    function getDesktopWnd (Handle: HWND; NotUsed: Longint): bool; stdcall; { Callback function } 
    VAR hChild : HWND; 
    begin 
    if handle <> 0 then 
    begin 
     hChild := FindWindowEx(handle, 0, 'SHELLDLL_DefView', nil); 
     if hChild <> 0 then 
     begin 
     hChild := FindWindowEx(hChild, 0, 'SysListView32', nil); 
     if hChild <> 0 
     then DeskHandle := hChild; 
     end; 
    end; 
    Result:= TRUE; 
    end; 

begin 
DeskHandle := 0; 
EnumWindows(@getDesktopWnd, 0); 
Result:= DeskHandle; 
end; 

主な質問がある：私は、単一の関数として、このコードを書くことができますあるいは、少なくとも、私は取り除くことができます外部/グローバルvarの？

解決策：
ドキュメントには、2番目のパラメータはINパラメータにすぎないことが記載されています。

lParamに タイプ[IN]：LPARAM コールバック関数に渡されるアプリケーション定義の値。
https://msdn.microsoft.com/en-us/library/windows/desktop/ms633497%28v=vs.85%29.aspx

戻って結果を渡すためにそれを使用するために間違っているだろうか？

Answer 1

type 
    TMyData = record 
    Handle: HWND; 
    Pid: DWORD; 
    Caption: String; 
    ClassName: String; 
    end; 
    PMyData = ^TMyData; 

function GetWindowClass(const Handle: HWND): String; 
begin 
    SetLength(Result, MAX_PATH); 
    SetLength(Result, GetClassName(Handle, PChar(Result), Length(Result))); 
end; 

function GetWindowCaption(const Handle: HWND): String; 
begin 
    SetLength(Result, MAX_PATH); 
    SetLength(Result, GetWindowText(Handle, PChar(Result), Length(Result))); 
end; 

function EnumChildWindowsProc(Handle: THandle; MyData: PMyData): BOOL; stdcall; 
var 
    ClassName: String; 
    Caption: String; 
    Pid: DWORD; 
begin 
    ClassName := GetWindowClass(Handle); 
    Caption := GetWindowCaption(Handle); 

    Result := (ClassName = 'SysListView32') and (Caption = 'FolderView'); 
    if Result then 
    begin 
    MyData.Handle := Handle; 
    GetWindowThreadProcessId(Handle, MyData.Pid); 
    MyData.Caption := Caption; 
    MyData.ClassName := ClassName; 
    end; 

    // To continue enumeration, the callback function must return TRUE; 
    // to stop enumeration, it must return FALSE 
    Result := not Result; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    MyData: TMyData; 
begin 
    ZeroMemory(@MyData, SizeOf(MyData)); 
    EnumChildWindows(GetDesktopWindow, @EnumChildWindowsProc, NativeInt(@MyData)); 
    if MyData.Handle > 0 then 
    begin 
    ShowMessageFmt('Found Window in Pid %d', [MyData.Pid]); 
    end 
    else begin 
    ShowMessage('Window not found!'); 
    end; 
end; 

Answer 2

ローカル関数をコールバックとして使用することはできません。 @演算子を使用して関数を渡さなかった場合、コンパイラはそれをあなたに伝えていました。 （演算子を使用すると、引数は通常の型なしポインタに変換されるので、コンパイラはこれ以上チェックできません）。

コールバックをスタンドアロン関数にする必要があります。

コールバックと呼び出し元の間でデータを渡すには、2番目のパラメータ（現在はNotUsed）を使用します。たとえば、ハンドル変数にポインタを渡すと、コールバックはポインタを参照解除して結果を返す可能性があります。