xsltを使用してインクリメンタルノードの名前を固定ノード値に変更します。

Question

xslt 1.0を使用して、入力xmlから下の出力を取得します。あなたはそれを行う方法を提案してもらえますか？

Input xml: 
    <result> 
     <item0> 
     <Name>Customer1</Name> 
     <location>1360190</location> 
     </item0> 
    <item1> 
     <Name>Customer2</Name> 
     <location>1360190</location> 
    </item1> 
    </result> 

    Output xml: 
     <result> 
     <item> 
      <Name>Customer1</Name> 
      <location>1360190</location> 
     </item> 
     <item> 
      <Name>Customer2</Name> 
      <location>1360190</location> 
     </item> 
     </result> 

Answer 1

@LingamurthyCSは述べているように、アイデンティティは、以下に示すような各種のXPath 試合参照を持つ<item>ノードの名前を変更するトランスフォームとテンプレートを検討：

結果参照し、子供に適用-テンプレート付き要素：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output version="1.0" encoding="UTF-8" indent="yes" method="xml"/> 
<xsl:strip-space elements="*"/> 

    <!-- Identity Transform --> 
    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="result/*"> 
    <item> 
     <xsl:apply-templates select="*"/> 
    </item> 
    </xsl:template>    

</xsl:transform> 

項目参照して

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output version="1.0" encoding="UTF-8" indent="yes" method="xml"/> 
<xsl:strip-space elements="*"/> 

    <!-- Identity Transform --> 
    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/*/*"> 
    <item> 
     <xsl:copy-of select="*"/> 
    </item> 
    </xsl:template>    

</xsl:transform> 

：参照とコピーの子要素のSULT

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output version="1.0" encoding="UTF-8" indent="yes" method="xml"/> 
<xsl:strip-space elements="*"/> 

    <!-- Identity Transform --> 
    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="*[contains(name(), 'item')]"> 
    <item> 
     <xsl:apply-templates /> 
    </item> 
    </xsl:template>    

</xsl:transform>