私のバッチスクリプトが予期しない結果をもたらす理由をデバッグするには？

Question

このコードは機能しません。これは、ランダムな形質とバックストーリーを持つ名前を生成することになっています。なぜそれがうまくいかないのか分かりません。

@echo off 
:top 
echo ---------------------------------------- 
echo random name genorator 
echo ---------------------------------------- 
echo  1 genorate name 
echo  2 add more info 
echo  3 what is this 
set /p rand= 
if %rand% == 1 goto first 
if %rand% == 2 goto 2 
if %rand% == 3 goto 3 
:first 
if %random% == 0 set fname=tony 
if %random% == 1 set fname=pamb 
if %random% == 2 set fname=ape 
if %random% == 3 set fname=bob 
if %random% == 4 set fname=jonathan 
if %random% == 5 set fname=dave 
if %random% == 6 set fname=avery 
if %random% == 7 set fname=felica 
if %random% == 8 set fname=herman 
if %random% == 9 set fname=elana 
cls 
echo your new name is %fname% 
pause 
:2 
exit 
:3 
exit 

1を押すと「あなたの新しい名前は」と表示されます。

Answer 1

タイプで：

echo %random% 

、それはあなたを与えるものを参照してください。あなたには9より高い数字が与えられます。例：

c:\pax> echo %random% 
1644 

ここであなたの名前がどのように設定されるかを考えてみましょう。 ifの条件のどれも真ではないため、全く変更されないので、のままで、のスクリプトを実行する前に残ります。

あなたは9包括までの範囲ゼロで乱数を取得し、それに基づいて名前を設定したい場合は、あなたが使用することができます。

set /a "num = %random% %% 10" 
if %num% == 0 set fname=tony 
rem ... and so on 

---

あなたの名前場合にも、ということに注意してくださいリストが長くなる可能性がある場合は、「アレイ」など、cmd^（a）という高度な機能を使用することをお勧めします。たとえば、次のスクリプトは、これを実行する方法を示しています。

@echo off 
setlocal enableextensions enabledelayedexpansion 

rem This is the list of names to use. 

set namelist=tony pam george bob john dave avery felica herman 
set namelist=!namelist! elana pax guido henry fortescue 

rem Construct the array, consisting of a base name with "_<index>" suffix. 

set /a "count = 0" 
for %%n in (!namelist!) do (
    set fname_!count!=%%n 
    set /a "count = count + 1" 
) 

rem Use modulo to select random index. 

set /a "idx = !random! %% count" 

rem Use double indirection to get actual name. 

for /f %%a in ('echo fname_!idx!') do echo !%%a! 

endlocal 

---

^（a）のはい、私はそれが同じ文で使用されている言葉cmdとadvancedを考えるのは難しいを知っている、実際にはにはがあります。知られていない場合は、便利な機能がいくつかあります：