関数内の変数を連結できません

Question

私はSQL Server 2008 R2を実行しています。私は、アドレスの部分を連結し、画面に表示するためにフォーマットされた結果を返すスカラ関数を書いています。しかし、私が返すのは@Address変数です。都市、州、ジップ、国は決して価値に追加されません。これは単純でなければなりません。私は何を間違えているのですか？

これは私のスカラー関数である：

SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 
; 

ALTER FUNCTION [dbo].[fnScreenAddress] (@Id INT) 
RETURNS VARCHAR(50) 
WITH EXECUTE AS CALLER 
AS 
BEGIN 
    DECLARE @ScreenAddress VARCHAR(50), -- The return value 
      @Address VARCHAR(64), 
      @UnitNumber VARCHAR(16), 
      @City VARCHAR(50), 
      @State CHAR(2), 
      @PostalCode VARCHAR(16), 
      @CountryCode VARCHAR(16); 

    SELECT 
     @Address = [Address], 
     @UnitNumber = ISNULL([UnitNumber], ''), 
     @City = [City], 
     @State = [State], 
     @PostalCode = [PostalCode], 
     @CountryCode = ISNULL([CountryCode], '') 
    FROM  
     [dbo].[LPAddress] 
    WHERE 
     [ID] = @Id; 

    SET @ScreenAddress = @Address; 

    IF @City <> '' 
    BEGIN 
     SET @ScreenAddress = @ScreenAddress + ', '; 
    END; 

    SET @ScreenAddress = @ScreenAddress + @City; 

    IF @State <> '' 
    BEGIN 
     SET @ScreenAddress = @ScreenAddress + ', '; 
    END; 

    SET @ScreenAddress = @ScreenAddress + @State; 
    SET @ScreenAddress = @ScreenAddress + @PostalCode; 
    SET @ScreenAddress = @ScreenAddress + @CountryCode; 
    SET @ScreenAddress = LTRIM(RTRIM(@ScreenAddress)); 

    RETURN(@ScreenAddress); 
END; 

はそれをテストするために、私は、クエリウィンドウで次のコマンドを入力します。

：そして、私はこの結果セットを

select 
    id, address, city, state, postalcode, countrycode, 
    dbo.fnScreenAddress(id) as [ScreenAddress] 
from 
    lpaddress; 

を取得

Answer 1

はるかに単純なバージョンのようです.....

ALTER FUNCTION [dbo].[fnScreenAddress] 
(
    @Id     INT 
) 
RETURNS VARCHAR(4000) 
WITH EXECUTE AS CALLER 
AS 
BEGIN 
     DECLARE @ScreenAddress VARCHAR(4000); -- The return value 

SELECT @ScreenAddress = 
    STUFF( 
     ISNULL(', ' + NULLIF([Address] , '') , '') 
     + ISNULL(', ' + NULLIF([UnitNumber] , '') , '') 
     + ISNULL(', ' + NULLIF([City]  , '') , '') 
     + ISNULL(', ' + NULLIF([State]  , '') , '') 
     + ISNULL(', ' + NULLIF([PostalCode] , '') , '') 
     + ISNULL(', ' + NULLIF([CountryCode], '') , '') , 1,2,'') 
FROM [dbo].[LPAddress] 
WHERE [ID] = @Id 

     RETURN @ScreenAddress; 
END; 

重要な注意

私はスカラー関数は、パフォーマンスキラーであり、特別にこの特定の場合には機能が多くの行あなたのように何回も呼ばれる、この目的のためにスカラー関数を使用していないだろう選択が戻ります。より良いパフォーマンスを得るには、選択したクエリに関数のコードを追加するだけです。