構造体のstructからJSONデータを抽出します。

Question

deserializeJSON（クエリ）の出力を参照してください。各行について

、どのようにしてIDのみとDTIMEを抽出することができますか？以下は、私のコードです：

以下

<cfscript> 
    record=deserializeJSON(query_testing.data_test); 

    writeDump(record); 

</cfscript> 

は "query_testing.data_test" のサンプルデータです：

'{"id3": 
     {"DECISION":1, 
     "DTIME":"2013-10-18 16:17:28"}, 
    "id5": 
     {"DECISION":1, 
     "DTIME":"2013-10-09 15:43:35",} 
    }' 

Answer 1

<cfscript> 

    record = deserializeJSON(query_testing.data_test); 

    rows = []; 
    for (id in record) { 

     rows.add({ 
      id: reReplace(id, "^id", ""), 
      dtime: record[id].DTIME 
     }); 
    } 
    writeDump(rows); 

</cfscript> 

---

要求されるようにここでは、タグの変種と使用例があります：

<cfset record = deserializeJSON(query_testing.data_test)> 

<cfset rows = []> 
<cfloop collection="#record#" item="id"> 

    <cfset rows.add({ 
     id: reReplace(id, "^id", ""), 
     dtime: record[id].DTIME 
    })> 
</cfloop> 
<cfdump var="#rows#"> 

<!--- print as table ---> 
<cfoutput> 
    <table> 
     <tr> 
      <th>id</th> 
      <th>dtime</th> 
     </tr> 
     <cfloop array="#rows#" index="row"> 
      <tr> 
       <td>#encodeForHtml(row.id)#</td> 
       <td>#dateTimeFormat(row.dtime, "yyyy-mm-dd, HH:nn:ss")#</td> 
      </tr> 
     </cfloop> 
    </table> 
</cfoutput>