Perl可変範囲の質問

Question

私はPerlクラスを持っています。それはsort()方法を持っている、と私はそれがsort()機能内蔵に多かれ少なかれ同じになりたい：

$object->sort(sub ($$) { $_[0] <=> $_[1] }); 

しかし、私は行うことはできません。そのため、スコープの

$object->sort(sub { $a <=> $b }); 

。しかし、List :: Utilモジュールはreduce()でこれを行います。私はList :: Utilモジュールを見て、これを実現させるために、no strict 'vars'でかなり厄介なことをします。私はそれを試みたが、役に立たなかった。

reduce()は、適切な名前空間にエクスポートされているため、私のクラスはこれを行うことができません。私の理解では、関数が別の名前空間にしっかりと入っています。これは正しいのですか、それとも私の状況でこれを行うためのいくつかの（間違いなく恐ろしい、あまりアドバイスされていない）方法がありますか？

Answer 1

まあ、他の2つの答えは、右半分の両方です。

package Foo; 

use strict; 
use warnings; 

sub sort { 
    my ($self, $sub) = @_; 

    my ($pkg) = caller; 
    my @x = qw(1 6 39 2 5); 
    print "@x\n"; 
    { 
     no strict 'refs'; 
     @x = sort { 
      local (${$pkg.'::a'}, ${$pkg.'::b'}) = ($a, $b); 
      $sub->(); 
     } @x; 
    } 
    print "@x\n"; 

    return; 
} 


package main; 

use strict; 
use warnings; 

my $foo = {}; 
bless $foo, 'Foo'; 

$foo->sort(sub { $a <=> $b }); 
# 1 6 39 2 5 
# 1 2 5 6 39 

実際にオブジェクトの一部であるデータをソートするとします。

$aと$bを、Perlが探している発信者のパッケージにローカライズするには、callerという魔法が必要です。そのサブが呼び出されている間だけ存在するグローバル変数を作成しています。

warningsで「一度だけ使用された名前」が表示されます。私は、何とかこれを避けるために飛び越えることができるいくつかのフープがあると確信しています。

Answer 2

あなたは、サブルーチンコールの期間$aと$bの値を設定するthe local operatorを使用することができます。

sub sample 
{ 
    my $callback = shift; 
    for (my $i = 0; $i < @_; $i += 2) { 
     local ($a, $b) = @_[$i, $i + 1]; 
     $callback->(); 
    } 
}  

sample sub { print "$a $b\n" }, qw(a b c d e f g h i j); 

あなたは普通のサブルーチンではなく、メソッドを持っている場合、あなたはそれがさらに可能にすることができsortのように、コールバック関数の前にsubを使用する必要はありません。機能上のプロトタイプを使用します。

sub sample (&@) 

その後、あなたはこのようにそれを呼び出す呼び出す：

sample { print "$a $b\n" } qw(a b c d e f g h i j); 

方法は、しかし、プロトタイプの影響を受けていません。

Answer 3

Sub::Identifyを使用して、コードレファに関連付けられたパッケージ（stash_name）を見つけることができます。次に、必要に応じてそのパッケージに$ aと$ bを設定します。あなたの方法でそれを動作させるためにno strict 'refs'を使用する必要があるかもしれません。

はここで一般的なケースで動作するように修正eveeさんの答えです：

use strict; 
use warnings; 

package Foo; 

use Sub::Identify 'stash_name'; 

sub sort { 
    my ($self, $sub) = @_; 

    my $pkg = stash_name($sub); 
    my @x = qw(1 6 39 2 5); 
    print "@x\n"; 
    { 
     no strict 'refs'; 
     @x = sort { 
      local (${$pkg.'::a'}, ${$pkg.'::b'}) = ($a, $b); 
      $sub->(); 
     } @x; 
    } 
    print "@x\n"; 

    return; 
} 


package Sorter; 

sub compare { $a <=> $b } 

package main; 

use strict; 
use warnings; 

my $foo = {}; 
bless $foo, 'Foo'; 

$foo->sort(\&Sorter::compare); 

$foo->sort(sub { $b <=> $a });