VBAコードの実行が完了するまでExcelブックが開かない

Question

問題：コードの実行が完了するまでブックが開かれません。

詳細：コードを続行するために、別のファイルを開く必要があるループがあります。このファイルはインターネットからダウンロードして開く必要があります。ファイルが開かれていない場合、msgboxが表示され、ユーザーにファイルを開くように要求します。ファイルをダウンロードして開くにしても、他のコードがすべて実行されるまで開くことはありません。

私の考え：「リフレッシュ」のようなものがあります。これは、現在の状態を更新します。おそらく、既存のコードに何かを追加して、Excelワークブックをリフレッシュし、何か他のことが起こった場合にはそれを見てください。以下

コード：（コードは結構です、私は必要なもののために働く、問題は他のすべてのコードが完了するまで、ブックが開いていないということです）：

Private Function WorkbookActive() As Boolean 

' Loop until the correct workbook is open 
Do Until WorkbookActive = True 
    On Error Resume Next 
    If Workbooks("Rapport.csv") Is Nothing Then 
     If MsgBox("[Rapport.csv] - Workbook is currently not open." & vbNewLine & "Please download and open [Rapports.csv] and press OK", vbOKCancel, "Workbook not open") = vbCancel Then Exit Do 
     WorkbookActive = False 
    ElseIf Not Workbooks("Rapport.csv") Is Nothing Then 
     WorkbookActive = True 
    End If 
Loop 

End Function 

Answer 1

あなたが必要とするすべてのApplication.Ontimeを使ってループを間接的にすることです。 はApplication.Ontimeを使用してルーチンを再スケジューリング、代わりに（Excelがブロックされ続けて）あなたのVBAルーチン内のループの、

Sub IndirectLoop() 
    On Error Resume Next 
    Workbooks("Rapport.csv").Activate 
    If Err.Number = 0 Then Exit Sub ' Done! 
    If MsgBox("[Rapport.csv] - Workbook is currently not open." & vbNewLine & _ 
     "Please download and open [Rapports.csv] and press OK", _ 
     vbOKCancel, "Workbook not open") = vbCancel Then _ 
      Exit Sub ' loop cancelled by user 

    ' Pause VBA and reschedule the routine for 3 seconds later 
    ' Control passes here from VBA to excel to open the file by the user' 
    Application.OnTime Now + TimeSerial(0, 0, 3), "IndirectLoop" 
End Sub 

アイデアがある：あなたのループをこのように書き換えます。このテクニックは、VBAからExcelにある程度の時間（例えば、上記のコードでは3秒）のコントロールを渡し、何らかのアクティビティを実行できるようにします。つまり、あなたが待っているファイルを開きます。