動的に作成されたコンポーネントのイベントハンドラをDelphi 6で自動的に割り当てる方法はありますか？

Question

多くのイベントハンドラを含むデザインと実行時コンポーネントがあります。私は今それをTNewCompと呼ぶでしょう。私はTFormにTNewCompのインスタンスを作成し、設計時にプロパティエディタを使ってイベントスタブを特定のコードで埋めて、現在のイベントハンドラコードセットを使用するTNewcompの新しいインスタンスを作成できるようにしたいと思います。

これを行うには、TNewCompのコンストラクタを呼び出してから、新しいインスタンスのイベントハンドラのそれぞれに、デザイン時に作成されたTNewCompインスタンスを含むフォームにある対応するイベントスタブコードを割り当てます。だから私は、私はどうなる各イベントハンドラのTNewFormと呼ばれるフォームにFNewCompという名前の変数に代入TNewCompのインスタンスを持っている場合：

FNewComp.onSomething = TNewform.onSomething 
(... repeat for each event handler belonging to TNewComp ...) 

これは正常に動作しますが、私が追加した場合には、面倒で悪化しています新しいイベントハンドラをTNewCompに追加するには、イベントハンドラの割り当てを行うためにnewTComp（）関数を更新することを忘れないでください。新しいインスタンスを動的に作成するすべての固有のコンポーネントタイプについて、このプロセスをリンスして繰り返します。

おそらくプロパティ検査やその他のDelphi 6イントロスペクションテクニックを使用してこのプロセスを自動化する方法はありますか？

- roschler

Answer 1

次のコードを使用しました。作成時にDestオーナーに注意してください。一番安全な方法は、後でNilを渡してコンポーネントを自分で解放することです。

implementation uses typinfo; 

procedure CopyComponent(Source, Dest: TComponent); 
var 
    Stream: TMemoryStream; 
    TypeData : PTypeData; 
    PropList: PPropList; 
    i, APropCount: integer; 
begin 
    Stream:=TMemoryStream.Create; 
    try 
    Stream.WriteComponent(Source); 
    Stream.Position:=0; 
    Stream.ReadComponent(Dest); 
    finally 
    Stream.Free; 
    end; 

    TypeData := GetTypeData(Source.ClassInfo); 
    if (TypeData <> nil) then 
    begin 
    GetMem(PropList, SizeOf(PPropInfo)*TypeData^.PropCount); 
    try 
     APropCount:=GetPropList(Source.ClassInfo, [tkMethod], PropList); 
     for i:=0 to APropCount-1 do 
     SetMethodProp(Dest, PropList[i], GetMethodProp(Source, PropList[i])) 
    finally 
     FreeMem(PropList); 
    end; 
    end; 
end; 

Answer 2

1つのオプションは、ストリームに「適切に設定コンポーネント」を保存して、それがDelphiのIDE /ランタイムによって行われているかのように新しい、動的に作成されたコンポーネントにそのストレムをロードすることです。

もうひとつのオプションは、TypInfoユニットであるRTTIを使用することです。そこには機能GetPropListがあり、利用可能なイベント（TypeKind tkMethod）を照会できるようになり、GetMethodPropと​​を使用して、あるコンポーネントから他のコンポーネントへのイベントハンドラーをコピーできます。

Answer 3

私は、次のようにMakseeのソリューションを微調整：

function CopyComponent(Source: TComponent; Owner: TComponent = nil): TComponent; 
var 
    Stream: TMemoryStream; 
    TypeData : PTypeData; 
    PropList: PPropList; 
    i, APropCount: integer; 
begin 
    if not Assigned(Source) then 
     raise Exception.Create('(CopyComponent) The Source component is not assigned.'); 

    Result := TComponent.Create(Owner); 

    Stream := TMemoryStream.Create; 

    try 
     Stream.WriteComponent(Source); 
     Stream.Position := 0; 
     Stream.ReadComponent(Result); 
    finally 
     Stream.Free; 
    end; // try() 

    // Get the type data for the Source component. 
    TypeData := GetTypeData(Source.ClassInfo); 

    if (TypeData <> nil) then 
    begin 
     // Get the property information for the source component. 
     GetMem(PropList, SizeOf(PPropInfo) * TypeData^.PropCount); 

     try 
      // Get the properties count. 
      APropCount := GetPropList(Source.ClassInfo, [tkMethod], PropList); 

      // Assign the source property methods to the destination. 
      for i := 0 to APropCount - 1 do 
       SetMethodProp(Result, PropList[i], GetMethodProp(Source, PropList[i])) 

     finally 
      // Free the property information object. 
      FreeMem(PropList); 
     end; // try() 
    end; // if (TypeData <> nil) then 
end; 

新しいコンポーネントが、むしろ既存のコンポーネント参照（MakseeのバージョンでのDESTパラメータ）を渡すよりも、関数によって返されるようにするため。誰かがこの変形から生じる欠陥または問題を見ることができる場合は、コメントしてください。