このジェネリックをDelphiで記述することはできますか？

Question

私はいくつかのデータ型があります。

type 
    TICD10CodeMap = TObjectDictionary<string, TICD10LookupResult>; 
    TStringMap = TDictionary<string, string>; 
    TFMRecMap = TDictionary<string, TFilemanRecord>; 

、そのうちのいくつかの事例：

var 
    FICD10Codes: TICD10CodeMap; 
    FPatientTypes: TStringMap; 
    FPOVs: TFMRecMap; 
    FTreatmentTypes: TStringMap; 
    FTypesOfCare: TStringMap; 

をそして私は、私は私のデータことを発見するまで喜んで、そのメソッドを追加使用して、それらを移入された方法を持っていましたソースに重複するキーがある可能性があります。

は今、私はちょうど、それぞれの前にContainsKeyでコードを書くことができ、すべてが追加（）と何かをするが、私は賢いだろうと思った：

procedure AddPair<ValType, DictType: TDictionary<string, ValType>> 
    (Key: string; Val: ValType; 
    Dict: DictType); 
begin 
    if (Dict as TDictionary<string, ValType>).ContainsKey(Key) then 
    AddPair('Copy of ' + Key, Val, Dict) 
    else 
    Dict.Add(Key, Val); 
end; 

しかし、私はデルファイのためにあまりにも巧妙だそうです。まず、関数定義の本体にキャストがあります。それは不要であるようですが、AddPairにコールしようとするとコンパイラエラーが発生するという事実があります。 -だろう-より洗練されたAddPair<string, TStringMap>(s3, s2, FPatientTypes)は何Iのうち、デルファイになるだろう、私は欠けているいくつかの呪文が、そこには約

[dcc32 Error] uReverseVistaLookups.pas(127): E2515 Type parameter 'ValType' is not compatible with type 'System.Generics.Collections.TDictionary<System.string,System.string>' 

を文句を言いながら、素朴なAddPair(s3, s2, FPatientTypes)は私の両方の

[dcc32 Error] uReverseVistaLookups.pas(116): E2010 Incompatible types: 'ValType' and 'string' 
[dcc32 Error] uReverseVistaLookups.pas(116): E2010 Incompatible types: 'DictType' and 'System.Generics.Collections.TDictionary<System.string,System.string>' 

を取得しますここでやろうとしてるの？

Answer 1

D'oh。

ジェネリックに2つの型パラメータのための必要はありません：（！面倒なキャストなし）

procedure AddPair<ValType>(Key: string; Val: ValType; 
    Dict: TDictionary<string, ValType>); 

は書きやすいですし、何それが必要ありません。

Answer 2

TDictionaryを使用するのは奇妙な方法ですが、簡単に目的を達成するには、サブクラス化するだけです。

program Project1; 
{$APPTYPE CONSOLE} 
uses 
    Generics.Collections, SysUtils; 

type 
    TCopyKeyMap<TValue> = class(TDictionary<string, TValue>) 
    public 
     procedure AddWithCopy(const Key: string; const Value: TValue); 
    end; 
    TStringMap = TCopyKeyMap<string>; 

procedure TCopyKeyMap<TValue>.AddWithCopy(const Key: string; const Value: TValue); 
begin 
    if ContainsKey(Key) then 
    AddWithCopy('Copy of ' + Key, Value) 
    else 
    Add(Key, Value); 
end; 

var 
    sm : TStringMap; 
    sp : TPair<string, string>; 
begin 
    sm := TStringMap.Create; 
    try 
    sm.AddWithCopy('foo', 'bar'); 
    sm.AddWithCopy('foo', 'bat'); 
    sm.AddWithCopy('foo', 'bam'); 
    for sp in sm do WriteLn(Format('%s : %s', [sp.Key,sp.Value])); 
    finally 
    sm.Free; 
    end; 
    ReadLn; 
end.