複数の隠しサブフォルダを作成するためのvbscript

Question

ルートディレクトリc：\ testのすべてのフォルダに「pst」という名前のサブフォルダを作成するスクリプトがあります。 'pst'フォルダを隠すために、このスクリプトにどのようなコードを追加する必要がありますか？

folder_path = "c:\test" 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set folder = fso.GetFolder(folder_path) 
For each f in folder.SubFolders 
fso.CreateFolder(f & "\PST") 
next 

ご協力いただきまして誠にありがとうございます。

Answer 1

あなたはこのような何かを試すことができます：あなたがする必要があるのは、フォルダ属性で遊ぶ

Option Explicit 
Dim fso,folder_path,folder,f 
folder_path = "c:\test" 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set folder = fso.GetFolder(folder_path) 
For each f in folder.SubFolders 
'wscript.echo f & "\PST" 
    If Not fso.FolderExists(f & "\PST") Then 
     fso.CreateFolder(f & "\PST") 
     Call Hide(f & "\PST") 
    End If 
    If fso.FolderExists(f & "\PST") Then 
     Call Hide(f & "\PST") 
    End If 
Next 
'********************************************** 
Sub Hide(MyFolder) 
    Dim Command,Result,Ws 
    Command = "Cmd /c attrib +h " & DblQuote(MyFolder) &"" 
'wscript.echo Command 
    Set Ws = CreateObject("Wscript.Shell") 
    Result = Ws.Run(Command,0,True) 
End Sub 
'********************************************** 
Function DblQuote(Str) 
    DblQuote = Chr(34) & Str & Chr(34) 
End Function 
'********************************************** 

Answer 2

です。

Const Directory = 16 
Const Hidden = 2 

folder_path = "c:\test" 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set folder = fso.GetFolder(folder_path) 
For each f in folder.SubFolders 
    With fso.CreateFolder(fso.BuildPath(f, "PST")) 'returns folder object 
     .Attributes = Directory Or Hidden 'set hidden flag for directory 
    End With 
Next