バッチ - dirコマンドの出力を変数ディレクトリリストに格納

Question

ディレクトリリスト全体を変数に格納し、その変数をパラメータとして別のスクリプトに渡す必要があります。直接またはdirの出力をテキストファイルに保存してから次のようにします。

dir \path\todir > temp.txt 
set /p VAR=<temp.txt 

ただし、上記の行は1行しか読みません。助けてもらえますか？

Answer 1

最終目標に関するその他の情報は提供していないため、

私はperhapesは、このコードのような配列を簡単に変数を格納するためにあなたのアイデアを与える何かを投稿：

@echo off 
set "folder=%userprofile%\Desktop" 
setLocal EnableDelayedExpansion 
REM Populate the array with existent sub-folders in this folder 
for /f "tokens=* delims= " %%a in ('Dir /b /a:d "%folder%"') do (
    set /a N+=1 
    set "Folder[!N!]=%%a" 
) 
Rem Populate the array with existent files in this folder 
for /f "tokens=* delims= " %%a in ('Dir /b /a:-d "%folder%"') do (
    set /a M+=1 
    set "File[!M!]=%%a" 
) 
::***************************************************************** 
:Display_Folders 
cls & color 0E 
echo Just showing only Folders : 
echo(
For /L %%i in (1,1,%N%) do (
    echo Folder[%%i] = !Folder[%%i]! 
) 
echo(
echo Hit any key to show only files : 
pause>nul 
::***************************************************************** 
:Display_Files 
cls & color 0B 
echo Just showing only Files : 
echo(
For /L %%j in (1,1,%M%) do (
    echo File[%%j] = !File[%%j]! 
) 
echo(
echo Hit any key to exit : 
Pause>nul & exit