新しいプライマリキー（VBA）で重複レコード

Question

私は複製しようとしている非常に大きなレコードを持っているし、新しい主キーIDを持つ新しいバージョンでフォームを開きます。これは、データをコピーするためにすべてのフィールドを反復処理することなく、Access VBAで実行できますか？

ありがとうございます！

Answer 1

最速と最も簡単な方法は、DAOを使用することで、フォームのRecordsetClone：

Private Sub cmdDuplicate_Click() 

    Dim rstSource As DAO.Recordset 
    Dim rstInsert As DAO.Recordset 
    Dim fld   As DAO.Field 

    If Me.NewRecord = True Then Exit Sub 

    Set rstInsert = Me.RecordsetClone 
    Set rstSource = rstInsert.Clone 
    With rstSource 
    If .RecordCount > 0 Then 
     ' Go to the current record. 
     .Bookmark = Me.Bookmark 
     With rstInsert 
     .AddNew 
      For Each fld In rstSource.Fields 
      With fld 
       If .Attributes And dbAutoIncrField Then 
       ' Skip Autonumber or GUID field. 
       ElseIf .Name = "SomeFieldToPreset" Then 
       rstInsert.Fields(.Name).Value = SomeValue 
       ElseIf .Name = "SomeFieldToExclude" Then 
       ' Leave blank 
       Else 
       ' All other fields. 
       ' Copy field content. 
       rstInsert.Fields(.Name).Value = .Value 
       End If 
      End With 
      Next 
     .Update 
     ' Go to the new record and sync form. 
     .MoveLast 
     Me.Bookmark = .Bookmark 
     .Close 
     End With 
    End If 
    .Close 
    End With 

    Set rstInsert = Nothing 
    Set rstSource = Nothing 

End Sub 

これは新しいレコードに現在のレコードからフォームを移動します。これを簡単に変更して新しいIDを選択し、新しいレコードで他のフォームを開くことができます。

Answer 2

Duplicate Recordコマンドを参照してください。あなたはどちらかそれはボックス

から出てくると、それを使用するか、ウィザードによって生成されたコードを調査し、自分のためにカスタマイズすることができます。ウィザードを使用する方法では、PKが設定されている場合は、オートナンバー型のPKはコピーされません。