FORループの選択 - Windowsバッチ

Question

このループは、外部ファイルのすべての行について繰り返します。私は、これは動作しませんが、すべてのパスで選択肢のためのユーザーを促したいと思います。私は、GOTOコマンドを使ってループを何とか壊してしまうという問題があると思います。これについての考えは？

FOR /F %%i IN (%WORKDIR%\grunt-packages.ini) DO (
    CHOICE /C AN /M "Odinstalovat plugin" 
    IF %ERRORLEVEL%==1 GOTO UNINSTALL 
    IF %ERRORLEVEL%==2 GOTO SKIP 

    :UNINSTALL 
     ECHO Odstranuji %%i 
     CALL npm uninstall %%i 

    :SKIP 
     ECHO Preskakuji %%i 
) 

Answer 1

あなたの計算は正しいです。 forループ内のgotoはループを停止します。これを回避する方法は、代わりにcallを使用することです。しかし、スクリプトの最初の問題は、変数ERRORLEVELの遅延拡張の必要性です。カッコの範囲内に設定されている変数を展開するときは、遅延拡張を使用して最新の値を取得します。

SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR /F %%i IN (%WORKDIR%\grunt-packages.ini) DO (
    CHOICE /C AN /M "Odinstalovat plugin" 
    IF !ERRORLEVEL!==1 CALL :UNINSTALL 
    IF !ERRORLEVEL!==2 CALL :SKIP 
) 
ENDLOCAL 
GOTO :EOF 

:UNINSTALL 
    ECHO Odstranuji %%i 
    CALL npm uninstall %%i 
    GOTO :EOF 

:SKIP 
    ECHO Preskakuji %%i 
    GOTO :EOF 

1. gotoはforループ内で使用することができません。
2. カッコ内に設定された変数は、新しい値を取得するために遅延拡張が必要です。 %の代わりに!です。それ以外の場合は、カッコのスコープの前の変数の値が使用されます。

Answer 2

@メッツァーの答えは良いスタートだった（私はそれを投票した）が、いくつかの問題を見つけた。最後に、私はコードをインラインにして、CALLsを避ける方が好きです。ここに私のテストコードはどのように行うのを示すためにです：

@echo off 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%i IN (A B C D) DO (
    CHOICE /C AN /M "Uninstall plugin %%i" 
    IF !ERRORLEVEL!==1 (
     ECHO Uninstall %%i 
    ) ELSE IF !ERRORLEVEL!==2 (
     ECHO Skip %%i 
    ) 
) 

私は、Windows XP上のメッツガーの答え@テストし、以下の問題が見つかりました：Windows XP上GOTO :EOF（すでに固定）

を逃す

• サブルーチン、サブルーチンに%%iは、アンインストールがERRORLEVELを設定した場合、SKIPが

01と呼ばれるかもしれない

（潜在的なバグ）設定されていません

このテストコードは、問題が修正されています。

@echo off 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%i IN (A B C D) DO (
    CHOICE /C AN /M "Uninstall plugin %%i" 
    SET OERRORLEVEL=!ERRORLEVEL! 
    IF !ERRORLEVEL!==1 CALL :UNINSTALL %%i 
    IF !OERRORLEVEL!==2 CALL :SKIP %%i 
) 
ENDLOCAL 
GOTO :EOF 

:UNINSTALL 
    ECHO Uninstall %1 
    GOTO :EOF 

:SKIP 
    ECHO Skip %1 
    GOTO :EOF 

Answer 3

この構造は、華麗なDELAYEDEXPANSION

@ECHO OFF 
SETLOCAL 
FOR %%i IN (A B C D) DO (
SET destcall=BADCHOICE 
choice /c QJ /M "%%i - choose Q or J" 
IF ERRORLEVEL 1 SET destcall=CHOSEQ 
IF ERRORLEVEL 2 SET destcall=CHOSEJ 
CALL CALL :%%destcall%% 
) 
GOTO :eof 

:badchoice 
ECHO bad choice 
GOTO :eof 

:choseq 
ECHO You chose Q 
GOTO :eof 

:chosej 
ECHO You chose J 
GOTO :eof