文字列内の文字の出現を数える良い方法はありますか？

Question

私はLinuxでperlシェルでサブを書くのではなく、オカレンスをカウントする良い方法が必要だと感じました。 （あなたの4本のラインと比較して）文字列内の文字の出現箇所を数える

#/usr/bin/perl -w 
use strict; 
return 1 unless $0 eq __FILE__; 
main() if $0 eq __FILE__; 
sub main{ 
    my $str = "ru8xysyyyyyyysss6s5s"; 
    my $char = "y"; 
    my $count = count_occurrence($str, $char); 
    print "count<$count> of <$char> in <$str>\n"; 
} 
sub count_occurrence{ 
    my ($str, $char) = @_; 
    my $len = length($str); 
    $str =~ s/$char//g; 
    my $len_new = length($str); 
    my $count = $len - $len_new; 
    return $count; 
} 

Answer 1

は、Perlで一列で行うことができます。サブの必要はありません（ただし、サブの機能をカプセル化するのに間違いはありません）。 perlfaq4 "How can I count the number of occurrences of a substring within a string?"

use warnings; 
use strict; 

my $str = "ru8xysyyyyyyysss6s5s"; 
my $char = "y"; 
my $count =() = $str =~ /\Q$char/g; 
print "count<$count> of <$char> in <$str>\n"; 

Answer 2

から美しい *バッシュ/のCoreutils/Grepのワンライナーで：

$ str=ru8xysyyyyyyysss6s5s 
$ char=y 
$ fold -w 1 <<< "$str" | grep -c "$char" 
8 

それとも

$ grep -o "$char" <<< "$str" | wc -l 
8 

最初のものは、サブだけである場合にのみ機能します1文字長い。 2番目の部分は、部分文字列が重複していない場合にのみ機能します。

_{*実際にはありません。}

Answer 3

toolicが正しい答えを示していますが、プログラムを再利用できるようにハードコーディングしないことを検討することもできます。

use strict; 
use warnings; 

die "Usage: $0 <text> <characters>" if @ARGV < 1; 
my $search = shift;     # the string you are looking for 
my $str;        # the input string 
if (@ARGV && -e $ARGV[0] || !@ARGV) { # if str is file, or there is no str 
    local $/;       # slurp input 
    $str = <>;       # use diamond operator 
} else {        # else just use the string 
    $str = shift; 
} 
my $count =() = $str =~ /\Q$search\E/gms; 
print "Found $count of '$search' in '$str'\n"; 

これにより、プログラムを使用して、文字列、文字列、文字列、ファイル、または標準入力の出現をカウントできます。

count.pl needles haystack.txt 
some_process | count.pl foo 
count.pl x xyzzy 

Answer 4

文字が一定であれば、次は最高です：

my $count = $str =~ tr/y//; 

文字が可変である場合、私は次のように使用したい：例えば

my $count = length($str =~ s/[^\Q$char\E]//rg); 

私は」もしPerlが5.14より古いバージョンとの互換性を望むのであれば、次のコードを使用してください（遅くてメモリを増やすので）：

my $count =() = $str =~ /\Q$char/g; 

以下は何のメモリを使用しませんが、少し遅いかもしれません：

my $count = 0; 
++$count while $str =~ /\Q$char/g;