ExcelでVBAを使用してセルの値を条件付きでドロップダウンする方法

Question

Excel 2016でドロップダウンを試みていますが、頻繁には使用しないので、やり方を今はしません。

データは次のようになります。私は、列Eのセルの値に基づいて、「タイトル1」の値が含まれますドロップダウン、「タイトル2」、「TITLE3」を作成しようとしています

。他の言葉で

、このような何か：

if Cell E == 'index' 
    add Cell A value to dropdown 
end 

これを実現するための最良の方法だろうか？ Excel機能を使用してそれを行うことはできますか、またはVBAが必要ですか？そして、もしVBAが必要なら、どんなヒントも大いに評価されるでしょう。

Answer 1

（実際のニーズにそれを調整するためのコメントを参照してください）：

Sub Main() 
    With Worksheets("sheetWithDropDownName").Range("A1").Validation '<--| change "sheetWithDropDownName" and "A1" to your actual "dropdown" worksheet and cell references 
     .Delete 
     .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _ 
     xlBetween, Formula1:=Join(GetTitles(), ",") 
     .IgnoreBlank = True 
     .InCellDropdown = True 
     .InputTitle = "" 
     .ErrorTitle = "" 
     .InputMessage = "" 
     .ErrorMessage = "" 
     .ShowInput = True 
     .ShowError = True 
    End With 
End Sub 

Function GetTitles() As Variant 
    Dim cell As Range, rng As Range 

    With Worksheets("sheetWithDataName") '<--| change "sheetWithDataName" to your actual sheet with data name 
     Set rng = .Range("A1", .cells(.Rows.Count, "E").End(xlUp)) '<--| set a range as its columns A:E range from row 1 down to last column E not empty row 
    End With 
    With CreateObject("Scripting.Dictionary") 
     For Each cell In rng.Columns(5).cells 
      If cell.Value = "index" Then .Item(cell.Offset(, -4).Value) = cell.Offset(, -4).Value 
     Next cell 
     GetTitles = .keys 
    End With 
End Function 

Answer 2

VBAでは、このようなものが動作する可能性があります。コンボボックスはフォームにあり、データは "MyData"という名前のシートに置かれています。あなたはエクセルUIのドロップダウン細胞を扱っている場合、あなたはこのコードを使用する場合があります

Private Sub UserForm_Initialize() 
Dim lLastRow As Long 
Dim i As Integer 

lLastRow = Worksheets("MyData").Cells(Rows.Count, 1).End(xlUp).Row 

    For i = 2 To lLastRow 
     If Worksheets("MyData").Cells(i, 5) = "index" Then 
      ComboBox1.AddItem (Worksheets("MyData").Cells(i, 1)) 
     End If 
    Next 

End Sub