ラベルのクリックイベント

Question

私は約50のラベルを持つアプリケーションがあります。これらのラベルには数字が表示されます。 ユーザーがラベルをクリックすると、数字を編集ボックスに書き込む必要があります。 これはうまくいきますが、唯一の問題は、以下のような50個の関数を追加したときと同じときはいつでもそうです。私はこのための共通の機能があるのだろうかと思っていた 備考：ラベルには異なる名前があります。したがって、可能ならば、フォーム上のすべてのラベルに対してこれが有効になります。

Private Sub LI_L_Click(sender As Object, e As EventArgs) Handles LI_L.Click 
    cmbOBJID.Text = LI_L.Text 
End Sub 

Answer 1

フォームデザイナでは、すべてのラベルのハンドラを同じ機能に設定できる必要があります。次に、 "sender"パラメータを使用して、どのラベルがイベントを発生させているかを判断することができます。

機能がリンクしているすべてのコントロールは、「ハンドル」キーワードの後に​​リストされても、どのように注意してください。これは、Visual StudioのUIプロパティグリッドを使用する場合には、すべてのラベルにコードを接続する別の方法です。

Private Sub LI_Click(sender As Object, e As EventArgs) Handles Label1.Click, Label2.Click, Label3.Click 
    cmdOBJID.Text = DirectCast(sender, Label).Text 
End Sub 

Answer 2

それはそれはほんの数ラベルよりも長く退屈になります

Private Sub LI_Click(sender As Object, e As EventArgs) Handles Label1.Click, Label2.Click, Label3.Click 

のスタイルで1つのハンドラに複数のイベントを追加するのは簡単ですが。

ハンドラを追加する必要があるラベルを参照する方法が見つかると、ハンドラをプログラムで追加できます。この例では、私は「GroupBoxOptions」という名前のグループボックス内のすべてのラベルを置く：

Option Infer On 
Option Strict On 

Public Class Form1 

    Sub TransferDataToEditBox(sender As Object, e As EventArgs) 
     Dim lbl = DirectCast(sender, Label) 
     tbEditThis.Text = lbl.Text 

    End Sub 

    Sub InitLabelHandlers() 
     For Each lbl In GroupBoxOptions.Controls.OfType(Of Label) 
      AddHandler lbl.Click, AddressOf TransferDataToEditBox 
     Next 

    End Sub 

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
     InitLabelHandlers() 

    End Sub 

End Class 

あなたはハンドラを使用するラベルを選択するいくつかの他の方法を持っていることがあります。

Answer 3

フォーム上のすべてのラベルコントロールをトラバースして、ユーザーがラベルをクリックしたときに実行するイベントをAddHandler関数で割り当てることは、とても簡単ですばやいソリューションです。コードで

：

For Each c As Control In Me.Controls.OfType(Of Label) 
     AddHandler c.Click, AddressOf myLabelClick 
    Next 

prevousスニペット、タイプラベルのすべてのWinフォームコントロールの上に私たちのループ付き。そのようなループは、イベントを割り当てる必要のあるラベルがたくさんある場合に便利です。それぞれに対して、コントロールのClickイベントを、カスタマイズされたmyLabelClickという名前のSubに関連付けます。そのサブルーチンは、次のようになります。

Private Sub myLabelClick(sender As Object, e As EventArgs) 
    cmdObjId.Text = DirectCast(sender, Label).Text 
End Sub 

ここでは、そのTextプロパティにアクセスし、それに応じてcmdObjId.Textを変更する（クリックが行われたためにコントロールを表す）、送信者の変数を使用しています。