Excelでの値の貼り付けがマクロの式でない

Question

現在、あるシートのデータをコピーして別のシートに保存するマクロがあります。私が持っている問題は、式をコピーして貼り付けているだけで、値をコピーして貼り付ける必要があるということです。

Sub Archive_Execution() 

Dim mainworkbook As Workbook 
Set mainworkbook = ActiveWorkbook 
Dim rangeName 
Dim strDataRange As Range 
Dim keyRange As Range 

rangeName = "Archive_Execution" 
Application.Goto Reference:=rangeName 
Selection.Copy 
Sheets("Archive Execution").Activate 
Range("A" & Rows.Count).End(xlUp).Offset(1).Select 
mainworkbook.Sheets("Archive Execution").Paste 

Sheets("Archive Execution").Activate 
Set strDataRange = Range("A2:AA1000000") 
Set keyRange = Range("D1") 
strDataRange.Sort Key1:=keyRange, Order1:=xlAscending 

End Sub 

すべてのヘルプは大幅に値のみがコメントで述べたように式

Answer 1

ない貼り付けただけの値をコピーしたい場合はRange().PasteSpecial xlPasteValuesを使用しているように私のコードを微調整する上でいただければ幸いです。

IntersectメソッドとWorksheets("").UsedRangeを使用して範囲をトリミングすることもおすすめします。

Sub Archive_Execution() 

    Dim strDataRange As Range 
    Dim keyRange As Range 

    With Sheets("Archive Execution") 
     Range("Archive_Execution").Copy 
     .Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues 
    End With 

    With Sheets("Archive Execution") 
     Set strDataRange = Intersect(.Range("A2:AA" & .Rows.Count), .UsedRange) 
     Set keyRange = .Range("D1") 
     strDataRange.Sort Key1:=keyRange, Order1:=xlAscending 
    End With 

End Sub 

Answer 2

コピーアンドペーストを使用しないようにするには、コピー貼りよりはるかに高速です。

Sub Archive_Execution() 

    Dim mainworkbook As Workbook, rangeName 
    Dim strDataRange As Range, keyRange As Range 
    Dim r As Integer, c As Integer 

    Set mainworkbook = ActiveWorkbook 
    rangeName = "Archive_Execution" 
    r = Range(rangeName).Rows.Count 
    c = Range(rangeName).Columns.Count 

    With Sheets("Archive Execution").Range("A" & Rows.Count).End(xlUp).Offset(1) 
     .Resize(r, c) = Range(rangeName).Value 
    End With 

    Sheets("Archive Execution").Activate 
    Set strDataRange = Range("A2:AA1000000") 
    Set keyRange = Range("D1") 
    strDataRange.Sort Key1:=keyRange, Order1:=xlAscending 

End Sub