PerlでJSON :: PP :: Booleanを0,1に変換すると便利です。

Question

変換を試行していますJSONをYAMLに変換しようとしています。

--- 
some: 
    - isFlagged: !!perl/scalar:JSON::PP::Boolean 1 
    name: Some name 
    - isFlagged: !!perl/scalar:JSON::PP::Boolean 0 
    name: Some other name 

私は0または1にJSON::PP::Booleanオブジェクトを変換する必要があります。それが生成する。このコード

#!/usr/bin/env perl 

use 5.014; 
use warnings; 

use JSON; 
use YAML; 

my $json_string = q(
{ 
    "some" : [ 
     { "isFlagged" : true, "name" : "Some name" }, 
     { "isFlagged" : false, "name" : "Some other name" } 
    ] 
} 
); 

my $data = decode_json($json_string); 
say Dump($data); 

を持っています。もちろん、YAML出力から!!perl/scalar:JSON::PP::Boolean文字列をすべて削除することもできますが、これは正しい解決策ではないようです。

ので、簡単かつ正しい方法YAMLが

--- 
some: 
    - isFlagged: 1 
    name: Some name 
    - isFlagged: 0 
    name: Some other name 

Answer 1

使用YAMLのStringify optionを生成しますので、簡単な0と1にすべてJSON::PP::Booleanオブジェクトを変換するものである：

{ 
    local $YAML::Stringify = 1; 
    say Dump($data); 
} 

これはYAML使用しますオブジェクトの内部構造をダンプする代わりにJSON :: PP :: Booleanからオーバーロードされます。

Answer 2

一般解：

use Carp qw(carp); 

sub convert_bools { 
    my %unrecognized; 

    local *_convert_bools = sub { 
     my $ref_type = ref($_[0]); 
     if (!$ref_type) { 
      # Nothing. 
     } 
     elsif ($ref_type eq 'HASH') { 
      _convert_bools($_) for values(%{ $_[0] }); 
     } 
     elsif ($ref_type eq 'ARRAY') { 
      _convert_bools($_) for @{ $_[0] }; 
     } 
     elsif (
       $ref_type eq 'JSON::PP::Boolean'   # JSON::PP 
      || $ref_type eq 'Types::Serialiser::Boolean' # JSON::XS 
     ) { 
      $_[0] = $_[0] ? 1 : 0; 
     } 
     else { 
      ++$unrecognized{$ref_type}; 
     } 
    }; 

    &_convert_bools; 

    carp("Encountered an object of unrecognized type $_") 
     for sort values(%unrecognized); 
} 

my $data = decode_json($json); 
convert_bools($data);