clojureで、再帰を使用してマクロを実装するときにコードテンプレートを実行する方法

Question

マクロを実装して、インフィックスリストを接頭辞1に再帰的に変換しようとしています。次のような問題が発生しました。

;;this works 
(defmacro recursive-infix [form] 
    (list (second form) (first form) 
     (if (not (seq? (nth form 2))) 
      (nth form 2) 
      (recursive-infix (nth form 2))))) 

;;this doesn't work 
(defmacro my-recursive-infix [form] 
    `(~(second form) ~(first form) 
     (if (not (seq? ~(nth form 2))) 
      ~(nth form 2) 
      (my-recursive-infix ~(nth form 2))))) 

(macroexpand '(recursive-infix (10 + 10))) 
;;get (+ 10 10) 

(macroexpand '(my-recursive-infix (10 + 10))) 
;;get (+ 10 (if (clojure.core/not (clojure.core/seq? 10)) 10 (user/my-recursive-infix 10))) 

(recursive-infix (10 + 10)) 
;;get 20 

(my-recursive-infix (10 + 10)) 
;;Don't know how to create ISeq from: java.lang.Integer [Thrown class java.lang.IllegalArgumentException] 

問題はどこですか？コードテンプレートでマクロを正しく定義するには？

P.S.私はこれにコードを変更し、それは動作します、なぜですか？違い？：オリジナル版で

(defmacro my-recursive-infix [form] 
    (if (not (seq? (nth form 2))) 
    `(~(second form) ~(first form) ~(nth form 2)) 
    `(~(second form) ~(first form) (my-recursive-infix (nth form 2))))) 

Answer 1

何で、(if (not ...))チェックは、コンパイル時に起こっていました。あなたは代わりにそれを拡張コードに含めました。だから、あなたが望むように動かすことができる最小限の変更があります。それは事実上元のものと同じですが、引用されたものとそうでないものを「反転」させます。

(defmacro my-recursive-infix [form] 
    (let [third (nth form 2)] 
    `(~(second form) ~(first form) 
     ~(if (not (seq? third)) 
     third 
     `(my-recursive-infix ~third))))) 

しかし、それはむしろ、インプレースよりも、前もっての形の部分を引き出すために非構造を使用して少し立派です：

(defmacro my-recursive-infix [form] 
    (let [[x op y] form] 
    `(~op ~x ~(if (not (seq? y)) 
       y 
       `(my-recursive-infix ~y))))) 

、より良いまだ、本当に、移動することです外非再帰的な場合、（a）は、それは文字通りの数字のために働く、および（b）は、コードをよりそれがに展開するもののように見えるように：

(defmacro my-recursive-infix [form] 
    (if-not (seq? form) 
    form 
    (let [[x op y] form] 
     `(~op ~x (my-recursive-infix ~y)))))