sp_OAMethodを使用してテキストファイルに書き込むときに何も表示されない

Question

私は、入力を渡すことができるストアドプロシージャを使用してTransact-SQLでファイルに書き込もうとしています。ただし、SQL Server 2012でコマンドを実行するたびにCommand(s) completed successfully.と表示されますが、テキストファイルに移動してもテキストは表示されません。どんなアイデアが間違っている可能性がありますか？

マイコード：

 
    -- GRANTS PERMISSION TO OLE AUTOMATION -- 
    sp_configure 'show advanced options', 1; 
    GO 
    RECONFIGURE; 
    GO 
    sp_configure 'Ole Automation Procedures', 1; 
    GO 
    RECONFIGURE; 
    GO 

    DROP PROC WriteToGSQL; 

    -- ENCAPSULATING THE SPECIFIC CODE THAT DOES THE ACTUAL WRITING TO THE TEXT FILE -- 
    SET ANSI_NULLS ON 
    GO 
    SET QUOTED_IDENTIFIER ON 
    GO 
    CREATE PROC [dbo].[WriteToGSQL] 

    @Path  VARCHAR(2000), 
    @Text  VARCHAR(2000) 

    AS 

    BEGIN 

    DECLARE @Auto INT 
    DECLARE @FileID INT 

    EXECUTE sp_OACreate 'Scripting.FileSystemObject', @Auto OUT 
    EXECUTE sp_OAMethod @Auto, 'OpenTextFile', @FileID OUT, @Path, 8, 1 
    EXECUTE sp_OAMethod @FileID, 'WriteLine', Null, @Text 
    EXECUTE sp_OADestroy @FileID 
    EXECUTE sp_OADestroy @Auto 

    END 

    DECLARE @File VARCHAR(2000); 
    DECLARE @Txt VARCHAR(2000); 

    SET @File = 'C:\xxxxxxxx\xxxx\test.txt'; 
    SET @Txt = 'Did it work?'; 

    EXEC WriteToGSQL @File, @Txt; 

Answer 1

@JeroenMostertが正しい方向にあなたを指しているため、信用に値する、私はちょうどに沿ってあなたを助けるためにSQLの中に彼の言葉を入れている（と私はSSMSせずにそれをやっていますあなたは少しそれをつまむ必要があるかもしれないので、手に）。

Jeroenのポイントを繰り返し処理するには、戻り値をチェックして各sp_OA ...呼び出しが機能することを確認し、オブジェクトを破棄する前にファイルのCloseメソッドを呼び出す必要があります。さらに詳しい情報は、FileSystemObjectのMSDNドキュメントをご覧ください。

DECLARE @hr int; 

EXECUTE @hr = sp_OACreate 'Scripting.FileSystemObject', @Auto OUT 
IF @hr <> 0 
BEGIN 
    RAISERROR('Error %d creating object.', 16, 1, @hr) 
    RETURN 
END 

EXECUTE @hr = sp_OAMethod @Auto, 'OpenTextFile', @FileID OUT, @Path, 8, 1 
IF @hr <> 0 
BEGIN 
    RAISERROR('Error %d opening file.', 16, 1, @hr) 
    RETURN 
END 

EXECUTE @hr = sp_OAMethod @FileID, 'WriteLine', Null, @Text 
IF @hr <> 0 
BEGIN 
    RAISERROR('Error %d writing line.', 16, 1, @hr) 
    RETURN 
END 

EXECUTE @hr = sp_OAMethod @FileID, 'Close', Null, Null 
IF @hr <> 0 
BEGIN 
    RAISERROR('Error %d closing file.', 16, 1, @hr) 
    RETURN 
END 

EXECUTE @hr = sp_OADestroy @FileID 
EXECUTE @hr = sp_OADestroy @Auto