y軸に沿った陰影境界領域

Question

私は線をプロットしましたが、曲線下の領域を示すためにy軸に沿って2と4の間の領域を陰にしたいが、それを行う方法を理解できませんでした。これは、私はそれは難しいあなたが心を持っているだけで何地域を理解することを見つける

>y:=(2*x); 

>plot(y,x=0..3); 

Answer 1

かなり単純なコードです。

これはこれですか？もちろん

restart; 

y := 2*x: 

plots:-display(
    plot(2*x, x=0..3), 
    plots:-inequal([Y>=y, Y>=2, Y<=4], x=0..3, Y=0..6, 
       'nolines', 'color'="Burgundy") 
); 

あなたは上記のplotへの呼び出しを削除した曲線（ライン）y=2*x byを省略することができます。

他の地域を念頭に置いている場合は、それに応じてplots:-inequalへの通話を調整する必要があります。

filledオプションを使用してplotを呼び出すなど、他の方法を実行することもできます。 plottools:-reflectを使用することも、plotというパラメータ呼び出しシーケンスを使用して、xとy軸を反転することもできます。

私は（y=2*xのこの例では、あなたの頭の中でそれを行うことができていても）あなたがy=2とy=4に対応x値を取得するには、「xについて解く」することを避けるために望むかもしれないことを把握。

これは、plots:-inequalを使用するのが最も簡単だと思う理由です。

[編集：フォローアップのコメントのための約8長方形]

まず、わずかに異なる例、うまくいけば、より明確にするため。

restart; 

x:=arcsin(y/6): 

P := plots:-display(
    plot(x, y=2..5), 
    plots:-inequal([X<=x], y=2..5, X=0..1.2, 
       'nolines', 'color'=pink) 
): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    plottools:-transform((x,y)->[y,x])(P), 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

下和（長方形を使用して）の上部がStudent:-Calculus1パッケージからRiemannSumコマンドを使用して可視化することができます。 （またはseqコマンドを使用して、それらのコーナーの数式ですべてを構成することもできます）。

plots:-displayコマンドに渡す部分は、もちろん削除できます。

restart; 

with(Student:-Calculus1): 

x:=arcsin(y/6): 

P:=RiemannSum(x, y=2..5, method = upper, output = plot, 
       partition=8, 
       boxoptions=[filled=[color=pink,transparency=.5]], 
       caption=""): 

rP:=plottools:-transform((x,y)->[y,x])(P): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    rP, 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

あるいは、

restart; 

with(Student:-Calculus1): 

x:=arcsin(y/6): 

P:=RiemannSum(x, y=2..5, method = lower, output = plot, 
       partition=8, 
       boxoptions=[filled=[color=pink,transparency=.5]], 
       caption=""): 

rP:=plottools:-transform((x,y)->[y,x])(P): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    rP, 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

あなたの代わりに、曲線とx軸との間の領域を望んでいた場合は、すべてのこれらの例は、少し複雑になります。