KRLの歩道を調べたり、やり取りをするにはどうしたらいいですか？

Question

私はKRLのアプリ履歴を追跡するために使用しているトレイルを持っています。私はトレイルをデバッグする簡単な方法を探しています。現在トレイルにあるものを見て、それをクリアすることができます。

KRLの簡単な方法はありますか？

Answer 1

トレンドに何があるのか​​を確認する最も簡単な方法は、そのコンテンツをブラウザコンソールに出力することです。ルールセットを複数回実行した後

rule inspect_data_on_trail { 
    select when pageview ".*" 
    pre { 
    visitedDomains = ent:visitedDomains; 
    } 
    { 
    emit <| 
     console.log(visitedDomains); 
    |>; 
    } 
} 

放火犯出力：トレイルなど、明確な実体変数へ

、私は通常ちょうど私のアプリのの一部ではないドメイン上の選択ルールを書きますアプリがそのドメインで実行されているときにvaraiblesをクリアしてください。

rule clear_everything { 
    select when pageview "yahoo\.com" 
    { 
    notify("Cleared",":)") with sticky = true; 
    } 
    fired { 
    clear ent:visitedDomains; 
    } 
} 

全例アプリ：

ruleset a60x458 { 
    meta { 
    name "trail-debugging" 
    description << 
     trail-debugging 
    >> 
    author "Mike Grace" 
    logging on 
    } 

    rule put_data_onto_trail { 
    select when pageview ".*" 
    pre { 
     domain = page:url("domain"); 
    } 
    { 
     notify("Thanks for visiting #{domain}","You visit has been recorded") with sticky = true; 
    } 
    fired { 
     mark ent:visitedDomains with domain; 
    } 
    } 

    rule inspect_data_on_trail { 
    select when pageview ".*" 
    pre { 
     visitedDomains = ent:visitedDomains; 
    } 
    { 
     emit <| 
     console.log(visitedDomains); 
     |>; 
    } 
    } 

    rule clear_everything { 
    select when pageview "yahoo\.com" 
    { 
     notify("Cleared",":)") with sticky = true; 
    } 
    fired { 
     clear ent:visitedDomains; 
    } 
    } 

}