同じコンテンツを2回フローティングしないようにするにはどうすればよいですか？

Question

私のKynetxアプリはfloat_html()を使用してコンテンツでいっぱいの箱を作ります。

rule float_box { 
    select when pageview ".*" 
    pre { 
    content = << 
     <div id='messagebox'> 
     <h3>Floating Message Box</h3> 
     <ul id='my_list'></ul> 
     </div> 
    >>; // trippy 
    } 
    float_html("absolute","top:25px","right:20px",content); 
} 

rule fill_box { 
    select when pageview ".*" 
    foreach ["alpha","bravo","charlie"] setting (list_item) 
    append("#my_list", "<li>#{list_item}</li>"); 
} 

ブックマークレットからアプリ（a421x27）が使用されています。同じページでブックマークレットを2回クリックすると、ダブルコンテンツが表示されます。

ボックスが既に画面上にあることを検出して再利用する方法はありますか？

Answer 1

jQueryを使用してコンテンツを手動でフロートさせて、コンテンツがすでに存在するかどうかを確認できます。

ruleset a60x516 { 
    meta { 
    name "so-answer-example" 
    description << 
     so-answer-example 
    >> 
    author "Mike Grace" 
    logging on 
    } 

    rule float_box { 
    select when pageview ".*" 
    pre { 
     content = << 
     <div id='messagebox'> 
     <h3>Floating Message Box</h3> 
     <ul id='my_list'></ul> 
     </div> 
     >>; /// fixing syntax highlighting bug 
    } 
    { 
     emit <| 
     if ($K("#messagebox").length == 0) { 
      $K(content).css({ 
      "position": "absolute", 
      "top": "25px", 
      "right": "20px" 
      }).appendTo(document.body); 
     }; 
     |>; 
    } 
    } 

    rule fill_box { 
    select when pageview ".*" 
    foreach ["alpha","bravo","charlie"] setting (list_item) 
    { 
     append("#my_list", "<li>#{list_item}</li>"); 
    } 
    } 
} 

これは

サイドノートexample.com

---

に、このコードから複数回ブックマークレットをクリックした後のように見えるされているものです。

は必ず{}であなたの行動を包みます。アクションは1つのアクションしかない場合は{}で囲まれずにアクションが動作しますが、{}でアクションブロックをマークする習慣に入るのが最善です。