Excel VBA - 変数forループ

Question

私は2番目のループを正しく取得できないようです。私は値 'Persoonlijke prijslijst'のセルを探しています。私はこのセルを持っていると、私は2つ上がって8を削除する必要があります。私がデバッグするとき、それはtemp = 0と言うので、私は2番目のforループにあると推測します。

Dim i As Integer 
For i = 1 To 800 
    Range("C" & i).Select 
    If Range("C" & i).Value = "Persoonlijke prijslijst" Then 
     Dim temp As Integer 
     For temp = i - 2 To temp + 8 
      Range("C" & temp).EntireRow.Delete Shift:=xlToLeft 
     Next temp 
    End If 
Next i 

Answer 1

これはあなたの試みですか？ 800回ループすることなく、

Option Explicit 

Sub Sample() 
    Dim ws As Worksheet 
    Dim StrSearch As String 
    Dim i As Long 

    '~~> Change this to the relevant sheet name   
    Set ws = Sheets("Sheet1") 

    StrSearch = "Persoonlijke prijslijst" 

    With ws 
     For i = 800 To 1 Step -1 
      If .Range("C" & i).Value = StrSearch Then 
       .Rows(i - 2 & ":" & i + 5).Delete 
      End If 
     Next i 
    End With 
End Sub 

Answer 2

別の方法：

Sub testing() 

Dim rng As Range 
Dim fAddress As String 
Dim rngRows As Range 

With Sheet1.Range("C1:C800") 
    Set rng = .Find("Persoonlijke prijslijst") 
    If Not rng Is Nothing Then 
     fAddress = rng.Address 
     Do 
     If rngRows Is Nothing Then 
      Set rngRows = rows(rng.Row - 2 & ":" & rng.Row + 5) 
     Else 
      Set rngRows = Union(rngRows, rows(rng.Row - 2 & ":" & rng.Row + 5)) 
     End If 
      Set rng = .FindNext(rng) 
     Loop While Not rng Is Nothing And rng.Address <> fAddress 
    End If 
End With 

rngRows.EntireRow.Delete 

End Sub